---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

The graphics output in the Results tab was produced using SAS 9.2. Submitting the sample code with a release of SAS prior to 9.2 might produce different results.

 /* Set the graphics environment */
goptions reset=all border cback=white
         htitle=12pt;  

 /* Create data set WORK.SWIRL */
data swirl;
   do x=-5 to 5 by 0.25;
      do y=-5 to 5 by 0.25;
         if x+y=0 then z=0;
         else z=(x*y)*((x*x-y*y)/(x*x+y*y));
         output;
      end;
   end;
run;

 /* Define the title for the first plot */
title1 'Simple Contour Plot';

 /* Produce the contour plot */
proc gcontour data=swirl;
   plot y*x=z;
run;
quit; 

 /* Redefine the title for the second plot */
title1 'Representing Contour Levels with Patterns';

 /* Produce the contour plot */
proc gcontour data=swirl;
   plot y*x=z / pattern
                coutline=gray;
run;
quit; 

 /* Redefine the title for the third plot */
title1 'Joining the Patterns in a Contour Plot';

 /* Define axis and legend characteristics */
axis1 label=none value=('-5' ' ' '0' ' ' '5')
      width=2;
axis2 label=none value=('-5' ' ' '0' ' ' '5')
      width=2;

legend frame;

 /* Produce the contour plot */
proc gcontour data=swirl;
   plot y*x=z / pattern
                join
                haxis=axis1
                vaxis=axis2
                legend=legend1;
run;
quit;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information