Models fit with the REPEATED statement use the Generalized Estimating Equations (GEE) method to estimate the model. GEE is not a likelihood-based method, so statistics like AIC, which are commonly used to compare models, are not available. However, the QIC statistic is available for GEE models and is analogous to AIC. Beginning in SAS^® 9.2, the QIC and QICu statistics are provided by PROC GENMOD for GEE models. QIC can be used to find an acceptable working correlation structure for a given model. QIC and the related QICu statistic can be used to compare GEE models. QICu approximates QIC when the GEE model is correctly specified. QICu, defined as Q+2p, adds a penalty (2p) to the quasilikelihood (Q), where p is the number of parameters in the model. The models being compared do not need to be nested — that is, the parameters in one model do not need to be a subset of the parameters in the other model. When using QIC or QICu to compare two structures or two models, the model with the smaller statistic is preferred.

Another way to assess the specified correlation structure is to use the COVB option in the REPEATED statement when fitting a GEE model. This option displays both the robust and model-based variance-covariance matrices. If these matrices are substantially different, then you might want to consider specifying a different working correlation structure in the TYPE= option.

There is no statistical test to assess the difference in these matrices or the correctness of the working correlation structure in general. But note that the GEE method is robust to the choice of correlation structure. So, even if the selected structure does not match the true structure, the resulting estimates are still get statistically consistent.

Example

The following statements fit a series of GEE models using different structures to the data set shown in the "Getting Started" section of the GENMOD documentation. ODS OUTPUT statements are used to save the QIC statistics and the structure types. These data sets will be combined later to produce a summary table.

      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / type=exch;
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains "Structure"));
         run;
      data sum1; merge model qic; run;
      
      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / type=ind;
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains  "Structure"));
         run;
      data sum2; merge model qic; run;
      
      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / type=ar;
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains  "Structure"));
         run;
      data sum3; merge model qic; run;
      
      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / type=mdep(3);
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains  "Structure"));
         run;
      data sum4; merge model qic; run;
      
      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / logor=exch;
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains  "Structure"));
         run;
      data sum5; merge model qic; run;
      
      proc genmod data=six desc;
         class case city(ref="portage");
         model wheeze = city age smoke / dist=bin;
         repeated subject=case / logor=fullclust;
         ods output 
           geefitcriteria=qic(where=(criterion="QIC"))
           geemodinfo=model(where=(Label1 contains  "Structure"));
         run;
      data sum6; merge model qic; run;

The following statements combine the structure type and QIC data sets from the models into a single data set. The data set is then sorted by increasing QIC value and displayed.

      data summary; 
         set sum1-sum6; 
         run;
      proc sort; 
         by value; 
         run;
      proc print label; 
         id label1;
         var cvalue1 value;
         title  "Comparison of GEE Structures";
         title2 "Smaller QIC values are better";
         label label1="Model Type" cvalue1="Structure" value="QIC value";
         run;

The results suggest that the exchangeable alternating logistic regression (ALR) model and the AR1 GEE model are the best structures since they have the smallest QIC values. There is not a great deal of difference among the QIC values for the various models. However, since no measure of variability is available, it is not possible to test whether one structure is significantly better than another.

Operating System and Release Information