Time Scale Options (netdre10)

/****************************************************************/
/*          S A S   S A M P L E   L I B R A R Y                 */
/*                                                              */
/*    NAME: NETDRE10                                            */
/*   TITLE: Time Scale Options (netdre10)                       */
/* PRODUCT: OR                                                  */
/*  SYSTEM: ALL                                                 */
/*    KEYS: NETDRAW                                             */
/*   PROCS: CPM, NETDRAW                                        */
/*    DATA:                                                     */
/*                                                              */
/* SUPPORT:                             UPDATE:                 */
/*     REF: Example 10 from the NETDRAW Chapter(PM User's Guide)*/
/*    MISC:                                                     */
/*                                                              */
/****************************************************************/

data exmp1;
   format task $16. succesr1-succesr3 $16. ;
   input task &
         duration
         succesr1 &
         succesr2 &
         succesr3 & ;
   datalines;
Drill Well        4  Pump House     .             .
Pump House        3  Install Pipe   .             .
Power Line        3  Install Pipe   .             .
Excavate          5  Install Pipe   Install Pump  Foundation
Deliver Material  2  Assemble Tank  .             .
Assemble Tank     4  Erect Tower    .             .
Foundation        4  Erect Tower    .             .
Install Pump      6  .              .             .
Install Pipe      2  .              .             .
Erect Tower       6  .              .             .
;

proc cpm data=exmp1 date='1jan04'd out=sched;
   activity task;
   duration duration;
   successor succesr1 succesr2 succesr3;
   run;


title j=l h=1.5 ' Site: Old Well Road';
title2 j=l h=1.5 ' Date: January 1, 2004';
footnote j=r h=1.5 'Time Scale Options: Reference Breaks ';


proc netdraw data=sched graphics;
   actnet / act = task
            dur = duration
            succ = (succesr1-succesr3)
            dp compress separatearcs
            font=swiss htext=2
            timescale refbreak lrefbrk = 33
            carcs=cyan crefbrk = blue;
   run;


title j=l h=1.5 ' Site: Old Well Road';
title2 j=l h=1.5 ' Date: January 1, 2004';
footnote j=r h=1.5 'Time Scale Options: Linear Diagram ';

proc netdraw data=sched graphics;
   actnet / act = task
            dur = duration
            succ = (succesr1-succesr3)
            dp
            pcompress
            novcenter
            vmargin = 10
            separatearcs
            htext=2
            carcs=cyan
            id=(task)
            nodefid
            nolabel
            boxwidth=7
            timescale
            linear
            frame;
   run;