Resources

Meeting Project Deadlines (cpme03)

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: CPME03                                              */
 /*   TITLE: Meeting Project Deadlines (cpme03)                  */
 /* PRODUCT: OR                                                  */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS: CPM                                                 */
 /*   PROCS: CPM                                                 */
 /*    DATA:                                                     */
 /*                                                              */
 /* SUPPORT:                             UPDATE:                 */
 /*     REF: Example 3 from the CPM Chapter (PM User's Guide)    */
 /*    MISC:                                                     */
 /*                                                              */
 /****************************************************************/


 /* Activity-on-Arc representation of the project */
data widgaoa;
   input task $ 1-12 days tail head;
   datalines;
Approve Plan   5   1   2
Drawings      10   2   3
Study Market   5   2   4
Write Specs    5   2   3
Prototype     15   3   5
Mkt. Strat.   10   4   6
Materials     10   5   7
Facility      10   5   7
Init. Prod.   10   7   8
Evaluate      10   8   9
Test Market   15   6   9
Changes        5   9  10
Production     0  10  11
Marketing      0   6  12
Dummy          0   8   6
;


proc cpm data=widgaoa
         fbdate='1mar04'd interval=day;
   tailnode tail;
   headnode head;
   duration days;
   id task;
   run;

proc sort;
   by e_start;
   run;

title 'Meeting Project Deadlines';
title2 'Specification of Project Finish Date';
proc print;
   id task;
   var e_: l_: t_float f_float;
   run;


proc cpm data=widgaoa
         fbdate='1mar04'd
         date='1dec03'd interval=day;
   tailnode tail;
   headnode head;
   duration days;
   id task;
   run;

proc sort;
   by e_start;
   run;

title2 'Specifying Project Start and Completion Dates';
proc print;
   id task;
   var e_: l_: t_float f_float;
   run;