Software Development Project (netdrg01)
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: NETDRG01 */
/* TITLE: Software Development Project (netdrg01) */
/* PRODUCT: OR */
/* SYSTEM: ALL */
/* KEYS: NETDRAW */
/* PROCS: CPM, NETDRAW */
/* DATA: */
/* */
/* SUPPORT: UPDATE: */
/* REF: Examples from the Getting Started section */
/* (PM User's Guide) */
/* MISC: */
/* */
/****************************************************************/
data software;
format descrpt $20. ;
input descrpt & duration activity $ succesr1 $ succesr2 $ ;
datalines;
Initial Testing 20 TESTING RECODE .
Prel. Documentation 15 PRELDOC DOCEDREV QATEST
Meet Marketing 1 MEETMKT RECODE .
Recoding 5 RECODE DOCEDREV QATEST
QA Test Approve 10 QATEST PROD .
Doc. Edit and Revise 10 DOCEDREV PROD .
Production 1 PROD . .
;
title 'Software Project';
title2 'Data Set SOFTWARE';
proc print;
run;
pattern1 v=e c=green;
pattern2 v=e c=red;
title h=3 'Software Project';
proc netdraw graphics data=software;
actnet / act=activity htext=2
succ=(succesr1 succesr2)
pcompress separatearcs;
run;
data softnet;
input descrpt $char20.
duration 23-24
activity $ 27-34
succesor $ 37-44
_x_ _y_ ;
datalines;
Initial Testing 20 TESTING RECODE 1 1
Meet Marketing 1 MEETMKT RECODE 1 2
Prel. Documentation 15 PRELDOC DOCEDREV 1 3
Prel. Documentation 15 PRELDOC QATEST 1 3
Recoding 5 RECODE DOCEDREV 2 2
Recoding 5 RECODE QATEST 2 2
QA Test Approve 10 QATEST PROD 3 3
Doc. Edit and Revise 10 DOCEDREV PROD 3 1
Production 1 PROD 4 2
;
title 'Software Project';
title2 'Data Set SOFTNET';
proc print;
run;
title h=3 'Software Project';
title2 h=2 'Controlled Layout';
proc netdraw graphics data=softnet;
actnet / act=activity htext=1.25
succ=(succesor)
pcompress;
run;
proc cpm data=software
out=intro1
interval=day
date='01mar04'd;
id descrpt;
activity activity;
duration duration;
successor succesr1 succesr2;
run;
title 'Software Project';
title2 'Project Schedule';
proc print data=intro1 noobs;
id descrpt;
run;
title h=3 'Software Project';
title2 h=2 'Time-Scaled Diagram';
proc netdraw graphics data=intro1;
actnet / act=activity succ=(succ:)
separatearcs pcompress htext=2
timescale linear frame mininterval=week
id=(activity duration) nolabel nodefid;
run;