Resources

Line-printer Network Diagram (netdr1)

/****************************************************************/
/*          S A S   S A M P L E   L I B R A R Y                 */
/*                                                              */
/*    NAME: NETDR1                                              */
/*   TITLE: Line-printer Network Diagram (netdr1)               */
/* PRODUCT: OR                                                  */
/*  SYSTEM: ALL                                                 */
/*    KEYS: NETDRAW                                             */
/*   PROCS: CPM, NETDRAW                                        */
/*    DATA:                                                     */
/*                                                              */
/* SUPPORT:                             UPDATE:                 */
/*     REF: Example 1 from the NETDRAW Chapter (PM User's Guide)*/
/*    MISC:                                                     */
/*                                                              */
/****************************************************************/

data widget;
   format task $12. succ1-succ3 $12.;
   input task & days succ1 & succ2 & succ3 & ;
   datalines;
Approve Plan   5  Drawings      Study Market  Write Specs
Drawings      10  Prototype     .             .
Study Market   5  Mkt. Strat.   .             .
Write Specs    5  Prototype     .             .
Prototype     15  Materials     Facility      .
Mkt. Strat.   10  Test Market   Marketing     .
Materials     10  Init. Prod.   .             .
Facility      10  Init. Prod.   .             .
Init. Prod.   10  Test Market   Marketing     Evaluate
Evaluate      10  Changes       .             .
Test Market   15  Changes       .             .
Changes        5  Production    .             .
Production     0  .             .             .
Marketing      0  .             .             .
;


title 'Widget Manufacture';
options ps=32 ls=78;
proc netdraw data=widget lineprinter;
   actnet / activity=task successor=(succ1 succ2 succ3);
   run;

proc cpm data=widget out=sched
         date='1dec03'd;
   activity task;
   successor succ1 succ2 succ3;
   duration days;
   run;

options ps=45 ls=90;
title2 'Schedule Information';
proc netdraw data=sched lineprinter;
   actnet / activity=task
            successor=(succ1 succ2 succ3)
            duration = days;
   run;