SASŪ High-Performance Analytics Samples
The SAS High-Performance Analytics sample programs and install verification tests can be run only after you
edit and submit this file.
The file contains site-specific information about your environment so that the procedures can run successfully.
Details Section Examples for PROC HPREG
/****************************************************************/
/* S A S S A M P L E L I B R A R Y */
/* */
/* NAME: hpregdt */
/* TITLE: Details Section Examples for PROC HPREG */
/* */
/* PRODUCT: HPA */
/* SYSTEM: ALL */
/* KEYS: Model Selection, ODS GRAPHICS */
/* PROCS: HPREG */
/* */
/* SUPPORT: Robert Cohen */
/****************************************************************/
/****************************************************************/
/* Details Section: Class Variable Split Example */
/****************************************************************/
data splitExample;
length c2 $6;
drop i;
do i=1 to 1000;
c1 = 1 + mod(i,6);
if i < 250 then c2 = 'low';
else if i < 500 then c2 = 'medium';
else c2 = 'high';
x1 = ranuni(1);
x2 = ranuni(1);
y = x1+3*(c2 ='low') + 10*(c1=3) +5*(c1=5) + rannor(1);
output;
end;
run;
proc hpreg data=splitExample;
class c1(split) c2(order=data);
model y = c1 c2 x1 x2/orderselect;
selection method=forward;
run;