BOXCHART Statement: SHEWHART Procedure

Note: See Control Chart for the Subgroup Maximum in the SAS/QC Sample Library.

This example illustrates how to compute and display control limits for the maximum of a subgroup sample. Subgroup samples of 20 metal braces are collected daily, and the lengths of the braces are measured in centimeters. These data are analyzed extensively in Example 18.43. The box chart for LogLength (the log of length) shown in Output 18.43.3 indicates that the subgroup mean is in control and that the subgroup distributions of LogLength are approximately normal. The following statements save the control limits for the mean of the LogLength in a data set named Logllims:

data LengthData;
   set LengthData;
   LogLength=log(Length-105);
run;

proc shewhart data=LengthData;
   xchart LogLength*Day /
      nochart
      outlimits=Logllims;
run;

The next statements replace the control limits for the mean of LogLength with control limits for the maximum of LogLength:

data Maxlim;
   set LengthData;
   set Logllims;
   drop expmax stdmax;
   label _lclx_ = 'Lower Limit for Maximum of 20'
         _uclx_ = 'Upper Limit for Maximum of 20'
         _mean_ = 'Central Line for Maximum of 20';
   expmax = _stddev_*1.86748 + _mean_;
   stdmax = _stddev_*0.52507;
   _lclx_ = expmax - _sigmas_*stdmax;
   _uclx_ = expmax + _sigmas_*stdmax;
   _mean_ = expmax;
   call symput('avgmax',left(put(expmax,8.1)));
run;

The control limits are computed using the fact that the maximum of a sample of size 20 from a normal population with zero mean and unit standard deviation has an expected value of 1.86747 and a standard deviation of 0.52509; refer to Teichroew (1962) and see Table 18.12. Finally, the following statements create a box chart for LogLength that displays control limits for the subgroup maximum:

ods graphics off;
title 'Box Chart With Control Limits for the Subgroup Maximum';
symbol v=none;
proc shewhart data=LengthData limits=Maxlim;
   boxchart LogLength*Day /
      ranges
      serifs
      nohlabel
      nolegend
      xsymbol="Avg Max=&AVGMAX" ;
   label LogLength='Values of LogLength';
run;

The box chart, shown in Output 18.6.1, indicates that the maximum is in control because the tips of the upper whiskers fall within the control limits.

The SYMPUT call is used to pass the value of _MEAN_ in a macro variable to the SHEWHART procedure so that this value can be used to label the central line.

You can apply the variable replacement method shown here to data with sample sizes other than 20 by replacing the constants 1.86747 and 0.52509 with the appropriate values from Table 18.12. Austin (1973) describes a method for approximating these values. You can also use the preceding statements to display control limits for the subgroup minimum by changing the sign of the expected values in Table 18.12.

The variable replacement method can also be used to create a variety of box charts, including the modifications suggested by Iglewicz and Hoaglin (1987) and Rocke (1989).