EWMACHART Statement: MACONTROL Procedure

Note: See Exponentially Weighted Moving Average Chart in the SAS/QC Sample Library.

You can save the control limit parameters for an EWMA chart in a SAS data set; this enables you to use these parameters with future data (see Reading Preestablished Control Limit Parameters) or modify the parameters with a DATA step program.

The following statements read measurements from the data set Clips1 (see Creating EWMA Charts from Raw Data) and save the control limit parameters in a data set named Cliplim:

title 'Control Limit Parameters';
proc macontrol data=Clips1;
   ewmachart Gap*Day / weight    = 0.3
                       outlimits = Cliplim
                       nochart;
run;

The OUTLIMITS= option names the data set containing the control limit parameters, and the NOCHART option suppresses the display of the chart. The data set Cliplim is listed in Figure 9.7.

Note that the data set Cliplim does not contain the actual control limits but rather the parameters required to compute the limits.

The data set contains one observation with the parameters for process Gap. The variable _WEIGHT_ contains the weight parameter used to compute the EWMAs. The value of _MEAN_ is an estimate of the process mean, and the value of _STDDEV_ is an estimate of the process standard deviation . The value of _LIMITN_ is the nominal sample size associated with the control limits, and the value of _SIGMAS_ is the multiple of associated with the control limits. The variables _VAR_ and _SUBGRP_ are bookkeeping variables that save the process and subgroup-variable. The variable _TYPE_ is a bookkeeping variable that indicates that the values of _MEAN_ and _STDDEV_ are estimates rather than standard values. For more information, see OUTLIMITS= Data Set.

You can create an output data set containing the control limits and summary statistics with the OUTTABLE= option, as illustrated by the following statements:

title 'Summary Statistics and Control Limits';
proc macontrol data=Clips1;
   ewmachart Gap*Day / weight   = 0.3
                       outtable = Cliptab
                       nochart;
run;

The data set Cliptab is listed in Figure 9.8.

This data set contains one observation for each subgroup sample. The variable _EWMA_ contains the EWMAs. The variables _SUBX_, _SUBS_, and _SUBN_ contain the subgroup means, subgroup standard deviations, and subgroup sample sizes, respectively. The variables _LCLE_ and _UCLE_ contain the lower and upper control limits, and the variable _MEAN_ contains the central line. The variables _VAR_ and Day contain the process name and values of the subgroup-variable, respectively. For more information, see OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read Cliptab and display a EWMA chart (not shown here) identical to Figure 9.3:

title 'EWMA Chart for Gap Measurements';
proc macontrol table=Cliptab;
   ewmachart Gap*Day ;
run;

For more information, see TABLE= Data Set.