Customized E-Book

To quickly change the look of your EPUB output, specify the OPTIONS option in the ODS EPUB statement. The OPTIONS option specifies suboptions that do the following:

specify the author with the CREATOR= suboption
specify a description with the DESCRIPTION= suboption
specify a subject with the SUBJECT= suboption
specify a type with the TYPE= suboption

Because the HTML destination is open by default, it is good practice to close the HTML destination if you do not want HTML output. This saves system resources.

ods html close;

ods epub file="your-file-path/prdsaleBookCustom.epub"
    title="My First ODS EPUB E-book"
    options(creator="SAS Programmer" 
    description="Sales Figures for First Quarter by Product" 
    subject="PROC TABULATE, PROC UNIVARIATE, and PROC SGPANEL"
    type="ODS EPUB book");
 
title 'Actual Product Sales';
title2 '(millions of dollars)';

proc tabulate data=prdsale;   
    class region division prodtype;   
    classlev region division prodtype;   
    var actual;   
    keyword all sum;
    keylabel all='Total';   
    table (region all)*(division all),
         (prodtype all)*(actual*f=dollar10.) /
         misstext=[label='Missing']
         box=[label='Region by Division and Type']; 
 run;

title "PROC UNIVARIATE Output";
title2;
proc univariate data=prdsale;
    by Country;
    var actual;
run;

title 'Sales Figures for First Quarter by Product';

proc sgpanel data=prdsale;
    where quarter=1;
    panelby product / novarname;
    vbar region / response=predict;
    vline region / response=actual lineattrs=GraphFit;
    colaxis fitpolicy=thin;
    rowaxis label='Sales';
run;

title "PROC PRINT Output";
proc print data=sashelp.prdsale;
run;

ods epub close;

Customized E-Book Viewed in iBooks