Customized PowerPoint Output

To quickly change the look of your PowerPoint output, specify the STYLE= option in the ODS POWERPOINT statement. The STYLE= option with the PowerPointDark style specified tells ODS to use the PowerPointDark style instead of the default style. The output opens in PowerPoint. Because the HTML destination is open by default, it is good practice to close the HTML destination if you do not want HTML output. This saves system resources.

ods html close;

options nodate nonumber;
proc sort data=sashelp.prdsale out=prdsale;
    by Country;
run;

ods powerpoint file='your-file-path/PrdsaleCustom.ppt' style=PowerPointDark;
title 'Actual Product Sales';
title2 '(millions of dollars)';

proc tabulate data=prdsale;   
    class region division prodtype;   
    classlev region division prodtype;   
    var actual;   
    keyword all sum;
    keylabel all='Total';   
    table (region all)*(division all),
         (prodtype all)*(actual*f=dollar10.) /
         misstext=[label='Missing']
         box=[label='Region by Division and Type']; 
 run;

title "PROC UNIVARIATE Output";
title2;
proc univariate data=prdsale;
    by Country;
    var actual;
run;

title 'Sales Figures for First Quarter by Product';

proc sgpanel data=prdsale;
    where quarter=1;
    panelby product / novarname;
    vbar region / response=predict;
    vline region / response=actual lineattrs=GraphFit;
    colaxis fitpolicy=thin;
    rowaxis label='Sales';
run;

title "PROC PRINT Output";
proc print data=sashelp.prdsale;
run;

ods powerpoint close;

PROC SGPANEL Output Viewed in PowerPoint

PROC TABULATE Output Viewed in PowerPoint