Customized RTF Output

To quickly change the look of your RTF output, specify the STYLE= option in the ODS RTF statement. The STYLE= option with the Science style specified tells ODS to use the Science style instead of the default style for RTF output. Because the HTML destination is open by default, it is good practice to close the HTML destination if you do not want HTML output. This saves system resources.

ods html close;
options nodate nonumber;
proc sort data=sashelp.prdsale out=prdsale;
    by Country;
run;
ods rtf file='your-file-path/RTFPrdsaleCustom.rtf' style=Science;

title 'Actual Product Sales';
title2 '(millions of dollars)';

proc tabulate data=prdsale;   
    class region division prodtype;   
    classlev region division prodtype;   
    var actual;   
    keyword all sum;
    keylabel all='Total';   
    table (region all)*(division all),
         (prodtype all)*(actual*f=dollar10.) /
         misstext=[label='Missing']
         box=[label='Region by Division and Type']; 
 run;

title2;
title 'Sales Figures for First Quarter by Product';

proc sgpanel data=prdsale;
    where quarter=1;
    panelby product / novarname;
    vbar region / response=predict;
    vline region / response=actual lineattrs=GraphFit;
    colaxis fitpolicy=thin;
    rowaxis label='Sales';
run;
ods rtf close;

Even though you did not specify the STYLE= option in the PROC SGPANEL statement, the style=Science option in the ODS RTF statement applies the style for PROC SGPANEL, too.

Customized RTF Output Viewed in Microsoft Word