Relation Plot for the Insulation Data

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: RELRPLT1                                            */
 /*   TITLE: Relation Plot for the Insulation Data               */
 /* PRODUCT: QC                                                  */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS:                                                     */
 /*   PROCS: RELIABILITY                                         */
 /*    DATA: Nelson, W.  Accelerated Testing, pp. 135, 243       */
 /*     REF: SAS/QC Software: The RELIABILITY Procedure          */
 /*                                                              */
 /*                                                              */
 /****************************************************************/
 options nodate nostimer nonumber source2 ls=76 ps=80;

 data classb;
    input hours temp count censor;
    if _n_ = 1 then cntrl=1;
    else cntrl=0;
    cards;
       . 130  .  .
    8064 150 10  1
    1764 170  1  0
    2772 170  1  0
    3444 170  1  0
    3542 170  1  0
    3780 170  1  0
    4860 170  1  0
    5196 170  1  0
    5448 170  3  1
     408 190  2  0
    1344 190  2  0
    1440 190  1  0
    1680 190  5  1
     408 220  2  0
     504 220  3  0
     528 220  5  1
    ;

 title 'Relation Plot for Insulation Data';
 symbol1 c=red v=plus;
 symbol2 c=blue v=x;
 symbol3 c=green v=square;
 symbol4 c=yellow v=circle;
 proc reliability data = classb;
    distribution lognormal10;
    freq count;
    model hours*censor(1) = temp / relation = arr
                                   obstats(q=.1 .5 .9 control=cntrl);
    rplot hours*censor(1) = temp / pplot
                                   noconf
                                   plotdata
                                   plotfit 10 50 90
                                   fit      = model
                                   cframe   = ligr
                                   relation = arr
                                   lupper   = 1.e5
                                   slower   = 120 ;
 run;