Getting Started Example 3 for PROC RELIABILITY

/****************************************************************/
/*          S A S   S A M P L E   L I B R A R Y                 */
/*                                                              */
/*    NAME: RELGS3                                              */
/*   TITLE: Getting Started Example 3 for PROC RELIABILITY      */
/* PRODUCT: QC                                                  */
/*  SYSTEM: ALL                                                 */
/*    KEYS: reliability, lifetime data                          */
/*   PROCS: RELIABILITY                                         */
/*    DATA:                                                     */
/*                                                              */
/* SUPPORT: sasgjj                                              */
/*     REF: PROC RELIABILITY, INTRODUCTORY EXAMPLE 3.           */
/*    MISC:                                                     */
/****************************************************************/


data classb;
   input hours temp count censor;
   if _n_ = 1 then cntrl=1;
   else cntrl=0;
   label hours='Hours';
   datalines;
   . 130 .  .
8064 150 10 1
1764 170 1  0
2772 170 1  0
3444 170 1  0
3542 170 1  0
3780 170 1  0
4860 170 1  0
5196 170 1  0
5448 170 3  1
 408 190 2  0
1344 190 2  0
1440 190 1  0
1680 190 5  1
 408 220 2  0
 504 220 3  0
 528 220 5  1
;

proc print data=classb;
run;

proc reliability;
   distribution lognormal10;
   freq count;
   model hours*censor(1) = temp /
      relation = arr
      obstats(quantile = .1 .5 .9 control = cntrl);
   rplot hours*censor(1) = temp /
      pplot
      fit = model
      noconf
      relation = arr
      plotdata
      plotfit 10 50 90
      lupper = 1.e5
      slower = 120;
run;