Specifying the Position of the Inset

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: CAPIPOS                                             */
 /*   TITLE: Specifying the Position of the Inset                */
 /* PRODUCT: QC                                                  */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS: Capability Analysis, Insets,                        */
 /*   PROCS: CAPABILITY                                          */
 /*    DATA:                                                     */
 /*                                                              */
 /*     REF:                                                     */
 /*    MISC:                                                     */
 /*                                                              */
 /****************************************************************/

options ps=60 ls=80;

data boxes;
   label weight='Weight in Grams';
   input weight @@;
   cards;
30.26 31.23 71.96 47.39 33.93 76.15 42.21
81.37 78.48 72.65 61.63 34.90 24.83 68.93
43.27 41.76 57.24 23.80 34.03 33.38 21.87
31.29 32.48 51.54 44.06 42.66 47.98 33.73
25.80 29.95 60.89 55.33 39.44 34.50 73.51
43.41 54.67 99.43 50.76 48.81 31.86 33.88
35.57 60.41 54.92 35.66 59.30 41.96 45.32
;


Title 'Specifying Position of Inset Box';

 /* POS= Specified in Compass Coordinates */

proc capability data=boxes noprint;
   var weight;
   spec usl=80    lsl=20      target=50
       lusl=1     llsl=2     ltarget=20
       cusl=white clsl=white ctarget=yellow;
   hist / cframe   = gray
          cfill    = blue
          cbarline = white
          nospeclegend;
   inset lsl target usl / pos    = NE
                          header = 'Specification Limits'
                          cframe = white
                          ctext  = white
                          cfill  = blue;
run;

 /* POS= Specified as Margin Location */

proc capability data=boxes noprint;
   var weight;
   cdfplot / cframe=gray;
   inset mean std max min / pos    = RM
                            header = 'Summary Statistics';
run;

 /* POS= Specified in Data Units */

proc capability data=boxes noprint;
   var weight;
   hist / cframe   = gray
          cfill    = blue
          cbarline = white;
   inset sum var skewness kurtosis /
                pos      = (97.5,40) data
                refpoint = TR
                header   = 'Summary Statistics'
                cframe   = white
                ctext    = white
                cfill    = green;
run;

 /* POS= Specified in Percent Units */

proc capability data=boxes noprint;
   var weight;
   hist / cframe   = gray
          cfill    = blue
          cbarline = white;
   inset p1 p5 p95 p99 / pos      = (95,95)
                         refpoint = TR
                         header   = 'Percentiles'
                         cframe   = black
                         ctext    = black
                         cfill    = yellow;
run;

goptions reset=all;