The LIFETEST Procedure

Bone marrow transplant (BMT) is a standard treatment for acute leukemia. Klein and Moeschberger (1997) present a set of BMT data for 137 patients, grouped into three disease categories based on their status at the time of transplantation: acute lymphoblastic leukemia (ALL), acute myelocytic leukemia (AML) low-risk, and AML high-risk. During the follow-up period, some patients might relapse or some patients might die while in remission. Relapse and death in remission are competing events, and the disease-free survival time is the time from transplant to the occurrence of the earlier of these two events.

The following DATA step creates the data set Bmt. (This Bmt data set is not identical to the Sashelp.Bmt data set in Example 70.2, but both are derived from the same study.) The variable Disease denotes the disease group of a patient, which is either ALL, AML-low risk, or AML-high risk. The variable Dftime represents the disease-free survival time, which is the time to relapse, the time to death, or censored. The failure time is expressed in years by dividing the time in days by 356.25. The variable Status has three values: 0 for censored observations, 1 for relapsed patients, and 2 for patients who die before experiencing a relapse. The variable Gender, which indicates the gender of the BMT patients, is included to illustrate how to conduct a stratified test.

proc format;
   value diseaseLabel 1='ALL' 2='AML-Low Risk' 3='AML-High Risk';
   value genderLabel  0='Female' 1='Male';
run;

data Bmt;
   input Disease Dftime Status Gender@@;
   Dftime= Dftime / 365.25;
   label Dftime='Disease-Free Survival Time (Years)'
         Disease='Disease Group'; 
   datalines;
1       2081       0       1       1       1602    0       1
1       1496       0       1       1       1462    0       0
1       1433       0       1       1       1377    0       1
1       1330       0       1       1       996     0       1

   ... more lines ...   

3       625        1       0       3       48      1       0
3       273        1       1       3       63      2       1
3       76         1       1       3       113     1       0
3       363        2       1
;

For competing-risks data, PROC LIFETEST estimates the cumulative incidence function (CIF). If you have multiple samples of data, it estimates the CIF for each sample and compares the CIFs between samples by using Gray’s test (Gray 1988). The estimated CIF is a step function with a jump at each distinct time when the event of interest occurred. If there are a large number of such event times, the table of the estimated CIF could be quite lengthy. If you are interested in the cumulative incidence at specific time points, you can use the TIMELIST= option in the PROC LIFETEST statement to specify these time points, and PROC LIFETEST prints the CIF estimates only at these time points.

Consider relapse as the event of interest. The following statements use PROC LIFETEST to estimate the CIF for relapse. To designate relapse (Status=1) as the event of interest, you specify the option FAILCODE=1 in the TIME statement. The TIMELIST= option in the PROC LIFETEST statement specifies the time points to display the CIF estimate, at half a year, one year, one and a half years, two years, four years, and six years. The STRATA statement identifies the disease groups as different samples of data. The PLOTS= option requests a plot of the estimated CIF, with a inset that shows the p-value of Gray’s test.

ods graphics on;
proc lifetest data=Bmt plots=cif(test) timelist=0.5 1.0 1.5 2.0 4.0 6.0;
   time Dftime*Status(0)/eventcode=1;
   strata Disease / order=internal;
   format Disease diseaseLabel. Gender genderLabel.;
run;

Output 70.4.1 tabulates the number of patients in each disease group who experience the event of interest (relapse) and those who experience the competing event (death in remission).

Output 70.4.2 displays the CIF estimate of relapse for the ALL patients at the selected time points. The predicted CIF at half a year after transplant is 0.1842, with a 95% confidence interval of (0.0798, 0.3224). At two years after transplant, the estimated CIF is 0.3243, with a 95% confidence interval of (0.1778, 0.4787). It is not feasible to estimate the cumulative incidence at a time beyond the largest observed time, which is 5.6975 years in the ALL group. That is why the estimates are missing at six years.

Output 70.4.3 and Output 70.4.4 display the CIF estimates at the selected times for AML-low risk and AML-high risk patients, respectively.

Output 70.4.5 displays the homogeneity test of Gray (1988), which indicates strong evidence of a significant difference in the CIF for relapse among the three disease groups (p = 0.0028).

The PLOTS= option produces a plot of the estimated CIFs (Output 70.4.5). Note that the range of each curve is from 0 to the largest observed time of the corresponding disease group, which is 5.6975 years for ALL patients, 7.0335 years for AML-low risk patients, and 7.2279 years for AML-high risk patients. With PLOTS=CIF(TEST) specified, that plot displays the p-value of the homogeneity test for the disease groups. The cumulative incidences of relapse are smallest for the AML-low risk patients and highest for the AML-high risk patients, with the ALL patients in between.

Output 70.4.6: CIF Estimates of Relapse in Bone Marrow Transplant Study

When you specify the GROUP= option in the STRATA statement, PROC LIFETEST enables you to perform a stratified test to evaluate the homogeneity of the CIFs between groups. Consider Gender as the stratifying variable for the stratified test. You specify Gender in the STRATA statement with the GROUP=DISEASE option as follows:

proc lifetest data=bmt plots=cif(test );
   time Dftime*Status(0)/eventcode=1;
   strata Gender/group=Disease order=internal;
   format Disease diseaseLabel. Gender genderLabel.;
run;
ods graphics off;

PROC LIFETEST summarizes the number of events and censored observations in each disease group by gender (Output 70.4.7). PROC LIFETEST computes a separate CIF estimate for each disease category for the female patients (Output 70.4.8) and likewise for the male patients (not shown here).

Output 70.4.9 shows the results of the stratified test with a p-value of 0.0026, which is essentially the same as the p-value of the nonstratified test. The PLOTS= option creates a panel plot with two cells: one cell for female patients and the other cell for male patients. Each cell contains three CIF curves, one for each disease group (Output 70.4.10). Regardless of the gender of the patient, an AML-high risk patient is more likely to relapse than an ALL patient, and an ALL patient is more likely to relapse than an AML-low risk patient. This ordering of probabilities is revealed in the panel plots in Output 70.4.10.

Output 70.4.10: Panel Plots of CIFs for Relapse