The MIANALYZE Procedure

Example 57.7 Reading Logistic Model Results from PARMS= and COVB= Data Sets

This example creates data sets that contains parameter estimates and corresponding covariance matrices computed by a logistic regression analysis for a set of imputed data sets. These estimates are then combined to generate valid statistical inferences about the model parameters.

The following statements use PROC LOGISTIC to generate the parameter estimates and covariance matrix for each imputed data set:

proc logistic data=outfish;
   class Species;
   model Species= Height Width Height*Width/ covb;
   by _Imputation_;
   ods output ParameterEstimates=lgsparms
              CovB=lgscovb;
run;

The following statements display (in Output 57.7.1) the output logistic regression coefficients from PROC LOGISTIC for the first two imputed data sets:

proc print data=lgsparms (obs=8);
   title 'LOGISTIC Model Coefficients (First Two Imputations)';
run;

The following statements displays the covariance matrices associated with parameter estimates derived from the first two imputations in Output 57.7.2:

proc print data=lgscovb (obs=8);
   title 'LOGISTIC Model Covariance Matrices (First Two Imputations)';
run;

The following statements use the MIANALYZE procedure with input PARMS= and COVB= data sets:

proc mianalyze parms=lgsparms
               covb(effectvar=stacking)=lgscovb;
   modeleffects Intercept Height Width Height*Width;
run;

The "Variance Information" table in Output 57.7.3 displays the between-imputation, within-imputation, and total variances for combining complete-data inferences.

The "Parameter Estimates" table in Output 57.7.4 displays the combined parameter estimates with associated standard errors.