Some Measurement Models

H4: Full Measurement Model for Lord Data

Psychometric test theory involves many kinds of models that relate scores on psychological and educational tests to latent variables that represent intelligence or various underlying abilities. The following example uses data on four vocabulary tests from Lord (1957). Tests and have 15 items each and are administered with very liberal time limits. Tests and have 75 items and are administered under time pressure. The covariance matrix is read by the following DATA step:

data lord(type=cov);
   input _type_ $ _name_ $ W X Y Z;
   datalines;
n   . 649       .       .       .
cov W 86.3979   .       .       .
cov X 57.7751 86.2632   .       .
cov Y 56.8651 59.3177 97.2850   .
cov Z 58.8986 59.6683 73.8201 97.8192
;

The psychometric model of interest states that and are determined by a single common factor , and and are determined by a single common factor . The two common factors are expected to have a positive correlation, and it is desired to estimate this correlation. It is convenient to assume that the common factors have unit variance, so their correlation will be equal to their covariance. The error terms for all the manifest variables are assumed to be uncorrelated with each other and with the common factors. The model equations are

with the following assumptions:

The corresponding path diagram is shown in Figure 17.16.

Figure 17.16 Path Diagram: Lord Data

In Figure 17.16, error terms are not explicitly represented, but error variances for the observed variables are represented by double-headed arrows that point to the variables. The error variance parameters in the model are labeled with , , , and , respectively, for the four observed variables. In the terminology of confirmatory factor analysis, these four variables are called indicators of the corresponding latent factors and .

Figure 17.16 represents the model equations clearly. It includes all the variables and the parameters in the diagram. However, sometimes researchers represent the same model with a simplified path diagram in which unconstrained parameters are not labeled, as shown in Figure 17.17.

Figure 17.17 Simplified Path Diagram: Lord Data

This simplified representation is also compatible with the PATH modeling language of PROC CALIS. In fact, this might be an easier starting point for modelers. With the following rules, the conversion from the path diagram to the PATH model specification is very straightforward:

• Each single-headed arrow in the path diagram is specified in the PATH statement.

• Each double-headed arrow that points to a single variable is specified in the PVAR statement.

• Each double-headed arrow that points to two distinct variables is specified in the PCOV statement.

Hence, you can convert the simplified path diagram in Figure 17.17 easily to the following PATH model specification:

proc calis data=lord;
   path   
      W <--- F1, 
      X <--- F1, 
      Y <--- F2,  
      Z <--- F2; 
   pvar 
      F1 = 1.0, 
      F2 = 1.0,
      W X Y Z;
   pcov
      F1 F2;
run;

In this specification, you do not need to specify the parameter names. However, you do need to specify fixed values specified in the path diagram. For example, the variances of F1 and F2 are both fixed at 1 in the PVAR statement.

These fixed variances are applied solely for the purpose of model identification. Because F1 and F2 are latent variables and their scales are arbitrary, fixing their scales are necessary for model identification. Beyond these two identification constraints, none of the parameters in the model is constrained. Therefore, this is referred to as the "full" measurement model for the Lord data.

An annotated fit summary is displayed in Figure 17.18.

The chi-square value is 0.7030 (=1, =0.4018). This indicates that you cannot reject the hypothesized model. The standardized root mean square error (SRMSR) is 0.003, which is much smaller than the conventional 0.05 value for accepting good model fit. Similarly, the RMSEA value is virtually zero, indicating an excellent fit. The adjusted GFI (AGFI) and Bentler comparative fit index are close to 1, which also indicate an excellent model fit.

The estimation results are displayed in Figure 17.19.

All estimates are shown with estimates of standard errors in Figure 17.19. They are all statistically significant, supporting nontrivial relationships between the observed variables and the latent factors. Notice that each free parameter in the model has been named automatically in the output. For example, the path coefficient from F1 to W is named _Parm1.

Two results in Figure 17.19 are particularly interesting. First, in the table for estimates of the path coefficients, _Parm1 and _Parm2 values form one cluster, while _Parm3 and _Parm4 values from another cluster. This seems to indicate that the effects from F1 on the indicators W and X could have been the same in the population and the effects from F2 on the indicators Y and Z could also have been the same in the population. Another interesting result is the estimate for the correlation between F1 and F2 (both were set to have variance 1). The correlation estimate (_Parm9 in the Figure 17.19) is 0.8986. It is so close to 1 that you wonder whether F1 and F2 could have been the same factor in the population. These estimation results can be used to motivate additional analyses for testing the suggested constrained models against new data sets. However, for illustration purposes, the same data set is used to demonstrate the additional model fitting in the subsequent sections.

In an analysis of these data by Jöreskog and Sörbom (1979, pp. 54–56) (see also Loehlin 1987, pp. 84–87), four hypotheses are considered:

These hypotheses are ordered such that the latter models are less constrained. The hypothesis is the full model that has been considered in this section. The hypothesis specifies that there is really just one common factor instead of two; in the terminology of test theory, , , , and are said to be congeneric. Setting the correlation between F1 and F2 to 1 makes the two factors indistinguishable. The hypothesis specifies that and have the same true scores and have equal error variance; such tests are said to be parallel. The hypothesis also requires and to be parallel. Because is not constrained to 1 in , two factors are assumed for this model. The hypothesis says that and are parallel tests, and are parallel tests, and all four tests are congeneric (with also set to 1).

H3: Congeneric (One-Factor) Model for Lord Data

The path diagram for this congeneric (one-factor) model is shown in Figure 17.20.

Figure 17.20 H3: Congeneric (One-Factor) Model for Lord Data

The only difference between the current path diagram in Figure 17.20 for the congeneric (one-factor) model and the preceding path diagram in Figure 17.17 for the full (two-factor) model is that the double-headed path that connects F1 and F2 is fixed to 1 in the current path diagram. Accordingly, you need to modify only slightly the preceding PROC CALIS specification to form the new model specification, as shown in the following statements:

proc calis data=lord;
   path   
      W <--- F1, 
      X <--- F1, 
      Y <--- F2,  
      Z <--- F2; 
   pvar 
      F1 = 1.0, 
      F2 = 1.0,
      W X Y Z;
   pcov
      F1 F2 = 1.0; 
run;

This specification sets the covariance between F1 and F2 to 1.0 in the PCOV statement. An annotated fit summary is displayed in Figure 17.21.

The chi-square value is 36.2095 ( = 2, < 0.0001). This indicates that you can reject the hypothesized model at the 0.01 -level. The standardized root mean square error (SRMSR) is 0.0277, which indicates a good fit. Bentler’s comparative fit index is 0.9766, which is also a good model fit. However, the adjusted GFI (AGFI) is 0.8570, which is not very impressive. Also, the RMSEA value is 0.1625, which is too large to be an acceptable model. Therefore, the congeneric model might not be the one you want to use.

The estimation results are displayed in Figure 17.22. Because the model does not fit well, the corresponding estimation results are not interpreted.

Perhaps a more natural way to specify the model under hypothesis is to use only one factor in the PATH model, as shown in the following statements:

proc calis data=lord;
   path   
      W <--- F1, 
      X <--- F1, 
      Y <--- F1,  
      Z <--- F1; 
   pvar 
      F1 = 1.0, 
      W X Y Z;
run;

This produces essentially the same results as the specification with two factors that have perfect correlation.

H2: Two-Factor Model with Parallel Tests for Lord Data

The path diagram for the two-factor model with parallel tests is shown in Figure 17.23.

Figure 17.23 H2: Two-Factor Model with Parallel Tests for Lord Data

The hypothesis requires that variables or tests under each factor are "interchangeable." In terms of the measurement model, several pairs of parameters must be constrained to have equal estimates. That is, under the parallel-test model W and X should have the same effect or path coefficient from their common factor F1, and they should also have the same measurement error variance . Similarly, Y and Z should have the same effect or path coefficient from their common factor F2, and they should also have the same measurement error variance . These constraints are labeled in Figure 17.23.

You can impose each of these equality constraints by giving the same name for the parameters involved in the PATH model specification. The following statements specify the path diagram in Figure 17.23:

proc calis data=lord;
   path   
      W <--- F1   = beta1,   
      X <--- F1   = beta1, 
      Y <--- F2   = beta2,  
      Z <--- F2   = beta2; 
   pvar 
      F1  = 1.0, 
      F2  = 1.0,
      W X = 2 * theta1,
      Y Z = 2 * theta2;
   pcov
      F1 F2; 
run;

Note that the specification 2*theta1 in the PVAR statement means that theta1 is specified twice for the error variances of the two variables W and X. Similarly for the specification 2*theta2. An annotated fit summary is displayed in Figure 17.24.

The chi-square value is 1.9335 (=5, =0.8583). This indicates that you cannot reject the hypothesized model H2. The standardized root mean square error (SRMSR) is 0.0076, which indicates a very good fit. Bentler’s comparative fit index is 1.0000. The adjusted GFI (AGFI) is 0.9970, and the RMSEA is close to zero. All results indicate that this is a good model for the data.

The estimation results are displayed in Figure 17.25.

Notice that because you explicitly specify the parameter names for the path coefficients (that is, beta1 and beta2), they are used in the output shown in Figure 17.25. The correlation between F1 and F2 is 0.8987, which is a very high correlation that suggests F1 and F2 might have been the same factor in the population. The next section sets this value to one so that the current model becomes a one-factor model with parallel tests.

H1: One-Factor Model with Parallel Tests for Lord Data

The path diagram for the one-factor model with parallel tests is shown in Figure 17.26.

Figure 17.26 H1: One-Factor Model with Parallel Tests for Lord Data

The hypothesis differs from in that F1 and F2 have a perfect correlation in . This is indicated by the fixed value 1.0 for the double-headed path that connects F1 and F2 in Figure 17.26. Again, you need only minimal modification of the preceding specification for to specify the path diagram in Figure 17.26, as shown in the following statements:

proc calis data=lord;
   path   
      W <--- F1   = beta1,   
      X <--- F1   = beta1, 
      Y <--- F2   = beta2,  
      Z <--- F2   = beta2; 
   pvar 
      F1  = 1.0, 
      F2  = 1.0,
      W X = 2 * theta1,
      Y Z = 2 * theta2;
   pcov
      F1 F2 = 1.0; 
run;

The only modification of the preceding specification is in the PCOV statement, where you put a constant 1 for the covariance between F1 and F2. An annotated fit summary is displayed in Figure 17.27.

The chi-square value is 37.3337 (=6, <0.0001). This indicates that you can reject the hypothesized model H1 at the 0.01 -level. The standardized root mean square error (SRMSR) is 0.0286, the adjusted GFI (AGFI) is 0.9509, and Bentler’s comparative fit index is 0.9785. All these indicate good model fit. However, the RMSEA is 0.0898, which does not support an acceptable model for the data.

The estimation results are displayed in Figure 17.28.

The goodness-of-fit tests for the four hypotheses are summarized in the following table.

Recall that the estimates of for and are almost identical, about 0.90, indicating that the speeded and unspeeded tests are measuring almost the same latent variable. However, when was set to 1 in and (both one-factor models), both hypotheses were rejected. Hypotheses and (both two-factor models) seem to be consistent with the data. Since is obtained by adding four constraints (for the requirement of parallel tests) to (the full model), you can test versus by computing the differences of the chi-square statistics and their degrees of freedom, yielding a chi-square of 1.23 with four degrees of freedom, which is obviously not significant. In a sense, the chi-square difference test means that representing the data by would not be significantly worse than representing the data by . In addition, because offers a more precise description of the data (with the assumption of parallel tests) than , it should be chosen because of its simplicity. In conclusion, the two-factor model with parallel tests provides the best explanation of the data.