Example 37.7 Log-Linear Model for Count Data

In this example the data, from Thall and Vail (1990), concern the treatment of people suffering from epileptic seizure episodes. These data are also analyzed in Diggle, Liang, and Zeger (1994). The data consist of the number of epileptic seizures in an eight-week baseline period, before any treatment, and in each of four two-week treatment periods, in which patients received either a placebo or the drug Progabide in addition to other therapy. A portion of the data is displayed in Table 37.12. See "Gee Model for Count Data, Exchangeable Correlation" in the SAS/STAT Sample Program Library for the complete data set.

Model the data as a log-linear model with (the Poisson variance function) and

where

number of epileptic seizures in interval

length of interval

The correlations between the counts are modeled as , (exchangeable correlations). For comparison, the correlations are also modeled as independent (identity correlation matrix). In this model, the regression parameters have the interpretation in terms of the log seizure rate displayed in Table 37.13.

The difference between the log seizure rates in the pretreatment (baseline) period and the treatment periods is for the placebo group and for the Progabide group. A value of indicates a reduction in the seizure rate.

Output 37.7.1 lists the first 14 observations of the data, which are arranged as one visit per observation:

Some further data manipulations create an observation for the baseline measures, a log time interval variable for use as an offset, and an indicator variable for whether the observation is for a baseline measurement or a visit measurement. Patient 207 is deleted as an outlier, as in the Diggle, Liang, and Zeger (1994) analysis.
The following statements prepare the data for analysis with PROC GENMOD:

data new;
   set thall;
   output;
   if visit=1 then do;
      y=bline;
      visit=0;
      output;
   end;
run;
 
data new;
   set new;
   if id ne 207;
   if visit=0 then do;
      x1=0;
      ltime=log(8);
   end;
   else do;
      x1=1;
      ltime=log(2);
   end;
run;

For comparison with the GEE results, an ordinary Poisson regression is first fit. The results are shown in Output 37.7.2.

The GEE solution is requested with the REPEATED statement in the GENMOD procedure. The SUBJECT=ID option indicates that the variable id describes the observations for a single cluster, and the CORRW option displays the working correlation matrix. The TYPE= option specifies the correlation structure; the value EXCH indicates the exchangeable structure.

The following statements perform the analysis:

proc genmod data=new;
   class id;
   model y=x1 | trt / d=poisson offset=ltime;
   repeated subject=id / corrw covb type=exch;
run;

These statements first fit a generalized linear model (GLM) to these data by maximum likelihood. The estimates are not shown in the output, but are used as initial values for the GEE solution.

Information about the GEE model is displayed in Output 37.7.3. The results of fitting the model are displayed in Output 37.7.4. Compare these with the model of independence displayed in Output 37.7.2. The parameter estimates are nearly identical, but the standard errors for the independence case are underestimated. The coefficient of the interaction term, , is highly significant under the independence model and marginally significant with the exchangeable correlations model.

Table 37.14 displays the regression coefficients, standard errors, and normalized coefficients that result from fitting the model with independent and exchangeable working correlation matrices.

The fitted exchangeable correlation matrix is specified with the CORRW option and is displayed in Output 37.7.5.

If you specify the COVB option, you produce both the model-based (naive) and the empirical (robust) covariance matrices. Output 37.7.6 contains these estimates.

The two covariance estimates are similar, indicating an adequate correlation model.