Example 37.6 Log Odds Ratios and the ALR Algorithm

Since the respiratory data in Example 37.5 are binary, you can use the ALR algorithm to model the log odds ratios instead of using working correlations to model associations. In this example, a "fully parameterized cluster" model for the log odds ratio is fit. That is, there is a log odds ratio parameter for each unique pair of responses within clusters, and all clusters are parameterized identically. The following statements fit the same regression model for the mean as in Example 37.5 but use a regression model for the log odds ratios instead of a working correlation. The LOGOR=FULLCLUST option specifies a fully parameterized log odds ratio model.

proc genmod data=resp descend;
   class id treatment(ref="P") center(ref="1") sex(ref="M")
      baseline(ref="0") / param=ref;
   model outcome=treatment center sex age baseline / dist=bin;
   repeated  subject=id(center) / logor=fullclust;
run;

The results of fitting the model are displayed in Output 37.6.1 along with a table that shows the correspondence between the log odds ratio parameters and the within-cluster pairs. Model goodness-of-fit criteria are shown in Output 37.6.2. The QIC for the ALR model shown in Output 37.6.2 is 511.86, whereas the QIC for the unstructured working correlation model shown in Output 37.5.4 is 512.34, indicating that the ALR model is a slightly better fit.

You can fit the same model by fully specifying the z matrix. The following statements create a data set containing the full z matrix:

data zin;
   keep id center z1-z6 y1 y2;
   array zin(6) z1-z6;
   set resp ;
   by center id;
   if first.id
      then do;
         t = 0;
         do m = 1 to 4;
            do n = m+1 to 4;
               do j = 1 to 6;
                  zin(j) = 0;
               end;
            y1 = m;
            y2 = n;
            t + 1;
            zin(t) = 1;
            output;
            end;
         end;
      end;
run;

proc print data=zin (obs=12);

Output 37.6.3 displays the full z matrix for the first two clusters. The z matrix is identical for all clusters in this example.

The following statements fit the model for fully parameterized clusters by fully specifying the z matrix. The results are identical to those shown previously.

proc genmod data=resp descend;
   class id treatment(ref="P") center(ref="1") sex(ref="M")
      baseline(ref="0") / param=ref;
   model outcome=treatment center sex age baseline / dist=bin;
   repeated  subject=id(center) / logor=zfull
                                  zdata=zin
                                  zrow =(z1-z6)
                                  ypair=(y1 y2) ;
run;