LISMOD <var_lists> ;

where var_lists represent one or more of the following:
YVAR  |  YV  |  Y = var_list
XVAR  |  XV  |  X = var_list
ETAVAR  |  ETAV  |  ETA = var_list
XIVAR  |  XIV  |  XI  |  KSIVAR  |  KSIV  |  KSI = var_list

LISMOD stands for LISREL modeling, where LISREL is the program developed by Jöreskog and Sörbom (1988). Like the original implementation of LISREL, LISMOD uses a matrix specification interface. To complete the LISMOD specification, you might need to add as many MATRIX statements as needed, as shown in the following statement structure for the LISMOD model:

LISMOD var_lists ;

MATRIX matrix-name parameters-in-matrix ;

Repeat the MATRIX statement as needed ;

The matrix-name in the MATRIX statement should be one of the twelve model matrices in LISMOD, as listed in the following:

• Matrices in the structural model: _ALPHA_, _KAPPA_, _BETA_, _GAMMA_, _PHI_, or _PSI_

• Matrices in the measurement model for -variables: _NUY_, _LAMBDAY_, or _THETAY_

• Matrices in the measurement model for -variables: _NUX_, _LAMBDAX_, or _THETAX_

See the section Model Matrices in the LISMOD Model for definitions of these matrices and their roles in the LISMOD modeling language. See the MATRIX statement for the details of parameter specification.

In the LISMOD statement, you can specify the following four lists of variables:

• YVAR= list is for manifest variables that are directly related to the endogenous latent variables (eta). Variables in the list are called -variables.

• XVAR= list is for manifest variables that are directly related to the exogenous latent variables (xi or ksi). Variables in the list are called -variables.

• ETAVAR= list is for endogenous latent variables . Variables in the list are called -variables.

• XIVAR= list is for exogenous latent variables . Variables in the list are called -variables.

The order of variables in the lists of the LISMOD statement is used to define the variable order in rows and columns of the LISMOD model matrices.

Depending on the model of interest, you might not need to specify all the lists of variables. When some variable lists are not specified, the full model reduces to specialized submodels. However, to be a proper submodel in the LISMOD modeling language, it is necessary (but not sufficient) that at least one of the YVAR= or XVAR= lists is defined. See the section LISMOD Submodels for the details about LISMOD submodels that PROC CALIS can handle.

An example of a LISMOD model specification is shown as follows:

proc calis;
   lismod xvar=x1-x3 yvar=y1-y6 xivar=xi etavar=eta1-eta2;
   matrix _LAMBDAY_   [,1]  = 1. load3 load4,
                      [,2]  = 0. 0. 0. 1. load5 load6;
   matrix _THETAY_    [1,1] = ey1-ey3,
                      [2,1] = cey;
   matrix _LAMBDAX_   [,]   = 1. load1 load2;
   matrix _THETAX_    [1,1] = 3*ex;
   matrix _GAMMA_     [,1]  = beta1 beta2;
   matrix _PHI_       [1,1] = phi;
   matrix _PSI_       [1,1] = psi1-psi2;
run;

In this example, you have three -variables x1–x3, six -variables y1–y6, one -variable xi, and two -variables eta1–eta2. The numbers of variables in these lists define the dimensions of the LISMOD model matrices. For example, matrix _LAMBDAY_ is , with y1–y6 as the row variables and eta1–eta2 as the column variables. Matrix _THETAX_ is , with x1–x3 as the row and column variables. In the MATRIX statements, you specify parameters in the elements of the matrices. After the matrix name, you specify in square brackets '[' and ']' the starting row and column numbers of the first element to be parameterized. After the equal sign, you specify fixed or free parameters for the matrix elements.

Depending on how you specify the starting row and column numbers, the parameter specification might proceed differently. See the MATRIX statement for a detailed description. In this example, the first specification of the parameters in the _LAMBDAY_ matrix starts from [,1]—meaning that it starts from the first column and proceeds downwards. As a result, the [1,1] element is a fixed constant , the [2,1] element is a free parameter called load3, and the [3,1] element is a free parameter called load4. Similarly, in the second specification in the _LAMBDAY_ matrix, the [1,2], [2,2], [3,2], and [4,2] elements take constant values 0, 0, 0, and 1, respectively, and the [5,2] and [6,2] elements are free parameters load5 and load6, respectively.

You can also use similar notation to specify the parameters of a row. For example, with the notation [2,] for the starting row and column numbers, specification proceeds to the left with the same second row in the matrix.

If you have specified both starting row and column numbers, such as those in the first specification in matrix _THETAY_, the parameter specification starts from [1,1] and proceeds to the next row and column numbers—that is [2,2], [3,3], and so on. This results in specifying the diagonal elements of matrix _THETAY_ as free parameters ey1, ey2, and ey3.

With the notation [,], no starting row and column numbers are specified. Specification starts from the first valid element in the matrix and proceeds row-wise for all valid elements in the matrix. For example, in the matrix _LAMBDAX_ statement, the [1,1] element of matrix _LAMBDAX_ is a fixed constant , and the [1,2] and [1,3] elements are free parameters load1 and load2, respectively.

proc calis;
   group 1 / data=d1;
   group 2 / data=d2;
   model 1 / group=1;
      lismod xvar=X1-X3 yvar=Y1-Y6 xivar=xi etavar=eta1-eta2;
      matrix _LAMBDAY_   [,1]  = 1. load3 load4,
                         [,2]  = 0. 0. 0. 1. load5 load6;
      matrix _THETAY_    [1,1] = ey1-ey3,
                         [2,1] = cey;
      matrix _LAMBDAX_   [,]   = 1. load1 load2;
      matrix _THETAX_    [1,1] = 3*ex;
      matrix _GAMMA_     [,1]  = beta1 beta2;
      matrix _PHI_       [1,1] = phi;
      matrix _PSI_       [1,1] = psi1-psi2;
   model 2 / group=2;
      refmodel 1;
      matrix _THETAY_    [2,1] = .;
      matrix _THETAX_    [1,1] = ex1-ex3;
      matrix _BETA_      [2,1] = beta;
   run;