Previous Page

|

Next Page

The SEQTEST Procedure

Example 78.3 Testing an Effect with Early Stopping to Accept

This example demonstrates a two-sided group sequential test that uses an error spending design with early stopping to accept the null hypothesis . The example is similar to Example 78.2 but with early stopping to accept .

A study is conducted to examine the effects of Age (years), Weight (kg), RunTime (time in minutes to run 1.5 miles), RunPulse (heart rate while running), and MaxPulse (maximum heart rate recorded while running) on Oxygen (oxygen intake rate, ml per kg body weight per minute). The primary interest is whether oxygen intake rate is associated with weight.

The hypothesis is tested using the following linear model:

The null hypothesis is , where is the regression parameter for the variable Weight. Suppose that is the reference improvement that should be detected at a level. Then the maximum information can be derived in the SEQDESIGN procedure.

Following the derivations in the section "Test for a Parameter in the Regression Model" in the chapter "The SEQDESIGN Procedure," the required sample size can be derived from

where is the variance of the response variable in the regression model, is the proportion of variance of Weight explained by other covariates, and is the variance of Weight.

Further suppose that from past experience, , , and . Then the required sample size can be derived using the SAMPLESIZE statement in the SEQDESIGN procedure.

The following statements invoke the SEQDESIGN procedure and request a three-stage group sequential design for normally distributed data to test the null hypothesis of a regression parameter against the alternative :

   ods graphics on;
   proc seqdesign altref=0.10;
      OBFErrorFunction: design method=errfuncgamma
                               stop=accept
                               nstages=3
                               info=cum(2 3 4)
                               ;
      samplesize model=reg( variance=5 xvariance=64 xrsquare=0.10);
   ods output Boundary=Bnd_Fit;
   run;
   ods graphics off;

By default, the procedure uses a Type I error probability and a Type II error probability . The ALTREF=0.10 option specifies a power of at the alternative hypothesis . The INFO=CUM(2 3 4) option specifies that the study perform the first interim analysis with information proportion —that is, after half of the total observations are collected.

The ODS OUTPUT statement with the BOUNDARY=BND_FIT option creates an output data set named BND_FIT which contains the resulting boundary information for the subsequent sequential tests.

The "Design Information" table in Output 78.3.1 displays design specifications and derived statistics. Since the alternative reference is specified, the maximum information is derived.

Output 78.3.1 Error Spending Design Information

The SEQDESIGN Procedure

Design: OBFErrorFunction

Design Information
Statistic Distribution	Normal
Boundary Scale	Standardized Z
Alternative Hypothesis	Two-Sided
Early Stop	Accept Null
Method	Error Spending
Boundary Key	Both
Alternative Reference	0.1
Number of Stages	3
Alpha	0.05
Beta	0.1
Power	0.9
Max Information (Percent of Fixed Sample)	103.9245
Max Information	1091.972
Null Ref ASN (Percent of Fixed Sample)	75.00521
Alt Ref ASN (Percent of Fixed Sample)	101.8099

The "Boundary Information" table in Output 78.3.2 displays information level, alternative reference, and boundary values at each stage.

With the specified ODS GRAPHICS ON statement, a detailed boundary plot with the rejection and acceptance regions is displayed by default, as shown in Output 78.3.3. The boundary plot also displays the information level and critical value for the corresponding fixed-sample design.

Output 78.3.3 Boundary Plot

With the MODEL=REG option in the SAMPLESIZE statement, the "Sample Size Summary" table in Output 78.3.4 displays the parameters for the sample size computation.

The "Sample Sizes" table in Output 78.3.5 displays the required sample sizes for the group sequential clinical trial.

Thus, , , and individuals are needed in stages , , and , respectively. Since the sample sizes are derived from estimated values of , , and , the actual information levels might not achieve the target information levels. Thus, instead of specifying sample sizes in the protocol, you can specify the maximum information levels. Then if an actual information level is much less than the target level, you can increase the sample sizes for the remaining stages to achieve the desired information levels and power.

Suppose that individuals are available at stage . Output 78.3.6 lists the first observations of the trial data.

The following statements use the REG procedure to estimate the slope and its associated standard error at stage :

   proc reg data=Fit_1;
      model Oxygen=Age Weight RunTime RunPulse MaxPulse;
      ods output ParameterEstimates=Parms_Fit1;
   run;

The following statements create and display (in Output 78.3.7) the input data set that contains slope and its associated standard error for the SEQTEST procedure:

   data Parms_Fit1;
      set Parms_Fit1;
      if Variable='Weight';
      _Scale_='MLE';
      _Stage_= 1;
      keep _Scale_ _Stage_ Variable Estimate StdErr;
   run;
   
   proc print data=Parms_Fit1;
      title 'Statistics Computed at Stage 1';
   run;

The following statements invoke the SEQTEST procedure to test for early stopping at stage :

   ods graphics on;
   proc seqtest Boundary=Bnd_Fit
                Parms(testvar=Weight)=Parms_Fit1
                boundaryadj=errfuncgamma
                stopprob
                order=lr
                ;
   ods output Test=Test_Fit1;
   run;
   ods graphics off;

The BOUNDARY= option specifies the input data set that provides the boundary information for the trial at stage , which was generated in the SEQDESIGN procedure. The PARMS=PARMS_FIT1 option specifies the input data set PARMS_FIT1 that contains the test statistic and its associated standard error at stage , and the TESTVAR=WEIGHT option identifies the test variable WEIGHT in the data set.

The ORDER=LR option uses the LR ordering to derive the -value, the unbiased median estimate, and the confidence limits for the regression slope estimate. The boundaries are adjusted using gamma cumulative error spending function, as specified with the BOUNDARYADJ= option.

The ODS OUTPUT statement with the TEST=TEST_FIT1 option creates an output data set named TEST_FIT1 which contains the updated boundary information for the test at stage . The data set also provides the boundary information that is needed for the group sequential test at the next stage.

The "Design Information" table in Output 78.3.8 displays the design specifications. By default, the boundary values are modified for the new information levels to maintain the Type I level. The maximum information remains the same as in the BOUNDARY= data set, but the derived Type II error probability and power are different because of the new information level.

With the STOPPROB option, the "Expected Cumulative Stopping Probabilities" table in Output 78.3.9 displays the expected stopping stage and the cumulative stopping probability of accepting the null hypothesis at each stage under various hypothetical references , where is the alternative reference and by default. You can specify other values for with the CREF= option.

The "Test Information" table in Output 78.3.10 displays the boundary values for the test statistic with the default standardized scale. The information level at stage is derived from the standard error in the PARMS= data set,

The information levels at stages and are derived proportionally from the corresponding information levels in the BOUNDARY= data set. See the section Boundary Adjustments for Information Levels for details about how these information levels are computed.

At stage , the standardized statistic is greater than the upper boundary , so the trial continues to the next stage.

With the specified ODS GRAPHICS ON statement, a boundary plot with test statistics is displayed by default, as shown in Output 78.3.11. As expected, the test statistic is in the continuation region.

Output 78.3.11 Sequential Test Plot

The following statements use the REG procedure to estimate the slope and its associated standard error at stage :

   proc reg data=Fit_2;
      model Oxygen=Age Weight RunTime RunPulse MaxPulse;
      ods output ParameterEstimates=Parms_Fit2;
   run;

Note that the data set Fit_2 contains both the data from stage and the data from stage ,

The following statements create and display (in Output 78.3.12) the input data set that contains slope and its associated standard error at stage for the SEQTEST procedure:

   data Parms_Fit2;
      set Parms_Fit2;
      if Variable='Weight';
      _Scale_='MLE';
      _Stage_= 2;
      keep _Scale_ _Stage_ Variable Estimate StdErr;
   run;
   
   proc print data=Parms_Fit2;
      title 'Statistics Computed at Stage 2';
   run;

The following statements invoke the SEQTEST procedure to test for early stopping at stage :

   ods graphics on;
   proc seqtest Boundary=Test_Fit1
                Parms(testvar=Weight)=Parms_Fit2
                boundaryadj=errfuncgamma
                order=lr
                pss
                plots=(asn power)
                ;
   ods output Test=Test_Fit2;
   run;
   ods graphics off;

The BOUNDARY= option specifies the input data set that provides the boundary information for the trial at stage , which was generated by the SEQTEST procedure at the previous stage. The PARMS= option specifies the input data set that contains the test statistic and its associated standard error at stage , and the TESTVAR= option identifies the test variable in the data set.

Since the data set PARMS_FIT2 does not contain the test information at stage , the information level at stage in the TEST_FIT1 data set is used to generate boundary values for the test.

The ORDER=LR option uses the LR ordering to derive the -value, unbiased median estimate, and confidence limits for the regression slope estimate.

The ODS OUTPUT statement with the TEST=TEST_FIT2 option creates an output data set named TEST_FIT2 which contains the updated boundary information for the test at stage . The data set also provides the boundary information that is needed for the group sequential test at the next stage.

The "Design Information" table in Output 78.3.13 displays design specifications. By default, the boundary values are modified for the new information levels to maintain the Type I level.

The derived Type II error probability and power are different because of the new information levels.

With the PSS option, the "Power and Expected Sample Sizes" table in Output 78.3.14 displays powers and expected mean sample sizes under various hypothetical references , where is the alternative reference and are the default values in the CREF= option.

With the PLOTS=ASN option, the procedure displays a plot of expected sample sizes under various hypothetical references, as shown in Output 78.3.15. By default, expected sample sizes under the hypotheses , , are displayed, where is the alternative reference.

Output 78.3.15 ASN Plot

With the PLOTS=POWER option, the procedure displays a plot of the power curves under various hypothetical references for all designs simultaneously, as shown in Output 78.3.16. By default, powers under hypothetical references are displayed, where by default. You can specify values with the CREF= option. The values are displayed on the horizontal axis.

Output 78.3.16 Power Plot

Under the null hypothesis, , the power is , which is the upper Type I error probability. Under the alternative hypothesis, , the power is , which is one minus the Type II error probability, as displayed in the "Design Information" table in Output 78.3.13.

The "Test Information" table in Output 78.3.17 displays the boundary values for the test statistic with the default standardized scale. At stage , the standardized slope estimate is between the lower and upper boundary values. The trial stops to accept the null hypothesis that the variable Weight has no effect on the oxygen intake rate after adjusting for other covariates.

Since the data set PARMS_FIT2 contains the test information only at stage , the information level at stage in the TEST_FIT1 data set is used to generate boundary values for the test.

With the specified ODS GRAPHICS ON statement, a boundary plot with test statistics is displayed by default, as shown in Output 78.3.18. As expected, the test statistic is in the acceptance region between the lower and upper boundaries at the final stage.

Output 78.3.18 Sequential Test Plot

After a trial is stopped, the "Parameter Estimates" table in Output 78.3.19 displays the stopping stage, parameter estimate, unbiased median estimate, confidence limits, and the -value under the null hypothesis . As expected, the -value is not significant at the level, and the confidence interval does contain the value zero. The -value, unbiased median estimate, and confidence limits depend on the ordering of the sample space , where is the stage number and is the standardized statistic. With the specified LR ordering, the -values are computed with the ordering if . See the section Available Sample Space Orderings in a Sequential Test for a detailed description of the LR ordering.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.