This example analyzes the data from Beitler and Landis (1985), which represent results from a multi-center clinical trial investigating the effectiveness of two topical cream treatments (active drug, control) in curing an infection. For each of eight clinics, the number of trials and favorable cures are recorded for each treatment. The SAS data set is as follows.

   data infection;
     input clinic t x n;
     datalines;
   1 1 11 36
   1 0 10 37
   2 1 16 20 
   2 0 22 32
   3 1 14 19
   3 0  7 19
   4 1  2 16
   4 0  1 17
   5 1  6 17
   5 0  0 12
   6 1  1 11
   6 0  0 10
   7 1  1  5
   7 0  1  9
   8 1  4  6
   8 0  6  7
   ;

Suppose denotes the number of trials for the th clinic and the th treatment (), and denotes the corresponding number of favorable cures. Then a reasonable model for the preceding data is the following logistic model with random effects:

and

The notation indicates the th treatment, and the are assumed to be iid .

The PROC NLMIXED statements to fit this model are as follows:

   proc nlmixed data=infection;
      parms beta0=-1 beta1=1 s2u=2;
      eta    = beta0 + beta1*t + u;
      expeta = exp(eta);
      p      = expeta/(1+expeta);
      model x ~ binomial(n,p);
      random u ~ normal(0,s2u) subject=clinic;
      predict eta out=eta;
      estimate '1/beta1' 1/beta1;
   run;

The PROC NLMIXED statement invokes the procedure, and the PARMS statement defines the parameters and their starting values. The next three statements define , and the MODEL statement defines the conditional distribution of to be binomial. The RANDOM statement defines u to be the random effect with subjects defined by the clinic variable.

The PREDICT statement constructs predictions for each observation in the input data set. For this example, predictions of and approximate standard errors of prediction are output to a data set named eta. These predictions include empirical Bayes estimates of the random effects .

The ESTIMATE statement requests an estimate of the reciprocal of .

The output for this model is as follows.