Some Measurement Models

Model Form D

with the following assumptions:

The corresponding path diagram is shown in Figure 17.10.

Figure 17.10 Path Diagram: Lord

With the following rules, the conversion from the path diagram to the PATH model specification is very straightforward:

• Each single-headed arrow in the path diagram is specified in the PATH statement.

• Each double-headed arrow that points to a single variable is specified in the PVAR statement.

• Each double-headed arrow that points to two distinct variables is specified in the PCOV statement.

Hence, this path diagram can be converted easily to a PATH model as follows:

   title 'H4: Unconstrained';
   proc tcalis data=lord outmodel=model4;
      path   
         w <- fwx    betaw,
         x <- fwx    betax,
         y <- fyz    betay,
         z <- fyz    betaz;
      pvar 
         fwx fyz = 2 * 1.0,
         w x y z = vew vex vey vez;
      pcov
         fwx fyz = rho;
   run;

The major results are displayed in Figure 17.11 and Figure 17.12.

It is convenient to create the OUTMODEL= data set called model4 for use in fitting other models with additional constraints. The same analysis can be performed with the LINEQS statement, as specified in the following:

   title 'H4: Unconstrained; LINEQS Specification';
   proc tcalis data=lord;
      lineqs w = betaw fwx + ew,
             x = betax fwx + ex,
             y = betay fyz + ey,
             z = betaz fyz + ez;
      std fwx fyz = 2 * 1.,
          ew ex ey ez = vew vex vey vez;
      cov fwx fyz = rho;
   run;

Unlike the PATH model specification, in the LINEQS specification you need to specify the error terms explicitly in the LINEQS statement. In the STD statement, you would need to specify the variance parameters for the exogenous variables, including both of the factors and the error terms. However, using the PATH model specification, no explicit names for error or disturbance terms are needed. As a result, the exogenous variance and error variance parameters are both specified in the PVAR statement. This treatment generalizes to the following useful rule about the PATH model specification:

• Each variable in the PATH model specification or path diagram should have a variance or partial variance parameter specified in the PVAR statement—as either an exogenous variance or a partial variance due to error.

The main results from the LINEQS model specification are displayed in Figure 17.13.

Aside from the output format, all estimates in the LINEQS model results in Figure 17.13 match those of the PATH model results in Figure 17.12. In some situations, the PATH and LINEQS statements might yield slightly different results due to the inexactness of the numerical optimization; the discrepancies can be reduced by specifying a more stringent convergence criterion such as GCONV=1E–4 or GCONV=1E–6.

Subsequent analyses are illustrated with the PATH statement rather than the LINEQS statement because it is easier to translate the path diagram to the PATH model specification.

In an analysis of these data by Jöreskog and Sörbom (1979, pp. 54–56; Loehlin 1987, pp. 84–87), four hypotheses are considered:

The hypothesis says that there is really just one common factor instead of two; in the terminology of test theory, , , , and are said to be congeneric. The hypothesis says that and have the same true scores and have equal error variance; such tests are said to be parallel. The hypothesis also requires and to be parallel. The hypothesis says that and are parallel tests, and are parallel tests, and all four tests are congeneric.

It is most convenient to fit the models in the opposite order from that in which they are numbered. The previous analysis fit the model for and created an OUTMODEL= data set called model4. The hypothesis can be fitted directly or by modifying the model4 data set. Since differs from only in that is constrained to equal 1, the model4 data set can be modified by finding the observation for which _NAME_=’rho’ and changing the variable _NAME_ to a blank value (meaning that the observation represents a constant rather than a parameter to be fitted) and by setting the variable _ESTIM_ to the value . The following statements create a new model stored in the model3 data set that is modified from the model4 data set:

   data model3(type=calismdl);
      set model4;
      if _name_='rho' then
         do;
            _name_=' ';
            _estim_=1;
         end;
   run;

In other words, the model information stored in data set model3 is specified exactly as hypothesis requires. This data set is then read as an INMODEL= data set for the following PROC TCALIS run:

   title 'H3: W, X, Y, and Z are congeneric';
   proc tcalis data=lord inmodel=model3;
   run;

Another way to specify the model under hypothesis is to specify the entire PATH model anew, such as in the following statements:

   title 'H3: W, X, Y, and Z are congeneric';
   proc tcalis data=lord;
      path  w <- f  betaw,
            x <- f  betax,
            y <- f  betay,
            z <- f  betaz;
      pvar 
         f = 1,
         w x y z = vew vex vey vez;
   run;

This would produce essentially the same results as those of the analysis based on the model stored in the data set model3. The main results from the analysis with the INMODEL=MODEL3 data set are displayed in Figure 17.14.

The hypothesis requires that several pairs of parameters be constrained to have equal estimates. With PROC TCALIS, you can impose this constraint by giving the same name to parameters that are constrained to be equal. This can be done directly in the PATH and PVAR statements or by using the DATA step to change the values in the model4 data set.

First, you can specify the model directly under the hypothesis ; the following PATH model is specified:

   title 'H2: W and X parallel, Y and Z parallel';
   proc tcalis data=lord;
      path
         w <- fwx   betawx,
         x <- fwx   betawx,
         y <- fyz   betayz,
         z <- fyz   betayz;
      pvar 
         fwx fyz = 2 * 1.0,
         w x y z = vewx vewx veyz veyz;
      pcov
         fwx fyz = rho;
   run;

Alternatively, if you use the DATA step to modify from the model4 data set, you would specify a new data set called model2 for storing the model information under the hypothesis , as shown in the following statements:

   data model2(type=calismdl);
      set model4;
      if _name_='betaw' then _name_='betawx';
      if _name_='betax' then _name_='betawx';
      if _name_='betay' then _name_='betayz';
      if _name_='betaz' then _name_='betayz';
      if _name_='vew' then _name_='vewx';
      if _name_='vex' then _name_='vewx';
      if _name_='vey' then _name_='veyz';
      if _name_='vez' then _name_='veyz';
   run;

Then you would use model2 as the INMODEL= data set in the following PROC TCALIS run:

   title 'H2: W and X parallel, Y and Z parallel';
   proc tcalis data=lord inmodel=model2;
   run;

The main results from either of these analyses are displayed in Figure 17.15.

The hypothesis requires one more constraint in addition to those in . Again, there are two ways to do this. First, a direct model specification is shown in the following statements:

   title 'H1: W and X parallel, Y and Z parallel, all congeneric';
   proc tcalis data=lord;
      path
         w <- f   betawx,
         x <- f   betawx,
         y <- f   betayz,
         z <- f   betayz;
      pvar 
         f       = 1.0,
         w x y z = vewx vewx veyz veyz;
   run;

Alternatively, you can modify the model2 data set to create a new data set model2 that stores the model information required by the hypothesis , as shown in the following statements:

   data model1(type=calismdl);
      set model2;
      if _name_='rho' then
         do;
            _name_=' ';
            _estim_=1;
         end;
   run;

You can then pass the model information stored in model1 as an INMODEL= data set in the following PROC TCALIS run:

   title 'H1: W and X parallel, Y and Z parallel, all congeneric';
   proc tcalis data=lord inmodel=model1;
   run;

The main results from either of these analyses are displayed in Figure 17.16.

The goodness-of-fit tests for the four hypotheses are summarized in the following table.

The hypotheses and , which posit , can be rejected. Hypotheses and seem to be consistent with the available data. Since is obtained by adding four constraints to , you can test versus by computing the differences of the chi-square statistics and their degrees of freedom, yielding a chi-square of with degrees of freedom, which is obviously not significant. So hypothesis is consistent with the available data.

The estimates of for and are almost identical, about 0.90, indicating that the speeded and unspeeded tests are measuring almost the same latent variable, even though the hypotheses that stated they measured exactly the same latent variable are rejected.