Previous Page

|

Next Page

The GLM Procedure

Example 39.1 Randomized Complete Blocks with Means Comparisons and Contrasts

This example, reported by Stenstrom (1940), analyzes an experiment to investigate how snapdragons grow in various soils. To eliminate the effect of local fertility variations, the experiment is run in blocks, with each soil type sampled in each block. Since these data are balanced, the Type I and Type III SS are the same and are equal to the traditional ANOVA SS.

First, the standard analysis is shown, followed by an analysis that uses the SOLUTION option and includes MEANS and CONTRAST statements. The ORDER=DATA option in the second PROC GLM statement is used so that the ordering of coefficients in the CONTRAST statement can correspond to the ordering in the input data. The SOLUTION option requests a display of the parameter estimates, which are produced by default only if there are no CLASS variables. A MEANS statement is used to request a table of the means with two multiple-comparison procedures requested. In experiments with focused treatment questions, CONTRAST statements are preferable to general means comparison methods. The following statements produce Output 39.1.1 through Output 39.1.4.

   title 'Balanced Data from Randomized Complete Block';
   data plants;
      input Type $ @;
      do Block = 1 to 3;
         input StemLength @;
         output;
         end;
      datalines;
   Clarion  32.7 32.3 31.5
   Clinton  32.1 29.7 29.1
   Knox     35.7 35.9 33.1
   O'Neill  36.0 34.2 31.2
   Compost  31.8 28.0 29.2
   Wabash   38.2 37.8 31.9
   Webster  32.5 31.1 29.7
   ;

   proc glm;
      class Block Type;
      model StemLength = Block Type;
   run;

   proc glm order=data;
      class Block Type;
      model StemLength = Block Type / solution;
    
   /*----------------------------------clrn-cltn-knox-onel-cpst-wbsh-wstr */
   contrast 'Compost vs. others'  Type   -1   -1   -1   -1    6   -1   -1;
   contrast 'River soils vs. non' Type   -1   -1   -1   -1    0    5   -1,
                                  Type   -1    4   -1   -1    0    0   -1;
   contrast 'Glacial vs. drift'   Type   -1    0    1    1    0    0   -1;
   contrast 'Clarion vs. Webster' Type   -1    0    0    0    0    0    1;
   contrast "Knox vs. O'Neill"    Type    0    0    1   -1    0    0    0;
   run;
    
       means Type / waller regwq;
   run;

Output 39.1.1 Analysis of Variance for Randomized Complete Blocks

Balanced Data from Randomized Complete Block

The GLM Procedure

Class Level Information
Class	Levels	Values
Block	3	1 2 3
Type	7	Clarion Clinton Compost Knox O'Neill Wabash Webster

Number of Observations Read	21
Number of Observations Used	21

Balanced Data from Randomized Complete Block

The GLM Procedure

 

Dependent Variable: StemLength

Source	DF	Sum of Squares	Mean Square	F Value	Pr > F
Model	8	142.1885714	17.7735714	10.80	0.0002
Error	12	19.7428571	1.6452381
Corrected Total	20	161.9314286

R-Square	Coeff Var	Root MSE	StemLength Mean
0.878079	3.939745	1.282668	32.55714

Source	DF	Type I SS	Mean Square	F Value	Pr > F
Block	2	39.0371429	19.5185714	11.86	0.0014
Type	6	103.1514286	17.1919048	10.45	0.0004

Source	DF	Type III SS	Mean Square	F Value	Pr > F
Block	2	39.0371429	19.5185714	11.86	0.0014
Type	6	103.1514286	17.1919048	10.45	0.0004

This analysis shows that the stem length is significantly different for the different soil types. In addition, there are significant differences in stem length among the three blocks in the experiment.

The GLM procedure is invoked again, this time with the ORDER=DATA option. This enables you to write accurate contrast statements more easily because you know the order SAS is using for the levels of the variable Type. The standard analysis is displayed again, this time including the tests for contrasts that you specified as well as the estimated parameters. These additional results are shown in Output 39.1.2.

The contrast label, degrees of freedom, sum of squares, Mean Square, F Value, and Pr > F are shown for each contrast requested. In this example, the contrast results indicate the following inferences, at the 5% significance level:

• The stem length of plants grown in compost soil is significantly different from the average stem length of plants grown in other soils.

• The stem length of plants grown in river soils is significantly different from the average stem length of those grown in nonriver soils.

• The average stem length of plants grown in glacial soils (Clarion and Webster types) is significantly different from the average stem length of those grown in drift soils (Knox and O’Neill types).

• Stem lengths for Clarion and Webster types are not significantly different.

• Stem lengths for Knox and O’Neill types are not significantly different.

In addition to the estimates for the parameters of the model, the results of tests about the parameters are also displayed. The ‘B’ following the parameter estimates indicates that the estimates are biased and do not represent a unique solution to the normal equations.

The final two pages of output (Output 39.1.3 and Output 39.1.4) present results of the Waller-Duncan and REGWQ multiple-comparison procedures. For each test, notes and information pertinent to the test are given in the output. The Type means are arranged from highest to lowest. Means with the same letter are not significantly different. For this example, while some pairs of means are significantly different, there are no clear equivalence classes among the different soils.

For an alternative method of analyzing and displaying mean differences, including high-resolution graphics, see Example 39.3.

Copyright © 2009 by SAS Institute Inc., Cary, NC, USA. All rights reserved.