PROC CATMOD: Mean Score Response Function, r=3 Responses :: SAS/STAT(R) 9.2 User's Guide, Second Edition

The CATMOD Procedure

Example 28.2 Mean Score Response Function, r=3 Responses

Four surgical operations for duodenal ulcers are compared in a clinical trial at four hospitals. The operations performed are as follows: Treatment $\text{[math]}$ a, drainage and vagotomy; Treatment $\text{[math]}$ b, 25% resection and vagotomy; Treatment $\text{[math]}$ c, 50% resection and vagotomy; and Treatment $\text{[math]}$ d, 75% resection. The response is severity of an undesirable complication called "dumping syndrome." The data in the following statements are from Grizzle, Starmer, and Koch (1969, pp. 489–504).

   data operate;
      input Hospital Treatment $ Severity $ wt @@;
      datalines;
   1 a none 23    1 a slight  7    1 a moderate 2
   1 b none 23    1 b slight 10    1 b moderate 5
   1 c none 20    1 c slight 13    1 c moderate 5
   1 d none 24    1 d slight 10    1 d moderate 6
   2 a none 18    2 a slight  6    2 a moderate 1
   2 b none 18    2 b slight  6    2 b moderate 2
   2 c none 13    2 c slight 13    2 c moderate 2
   2 d none  9    2 d slight 15    2 d moderate 2
   3 a none  8    3 a slight  6    3 a moderate 3
   3 b none 12    3 b slight  4    3 b moderate 4
   3 c none 11    3 c slight  6    3 c moderate 2
   3 d none  7    3 d slight  7    3 d moderate 4
   4 a none 12    4 a slight  9    4 a moderate 1
   4 b none 15    4 b slight  3    4 b moderate 2
   4 c none 14    4 c slight  8    4 c moderate 3
   4 d none 13    4 d slight  6    4 d moderate 4
   ;

The response variable (Severity) is ordinally scaled with three levels, so assignment of scores is appropriate (0 $\text{[math]}$ none, 0.5 $\text{[math]}$ slight, 1 $\text{[math]}$ moderate). For these scores, the response function yields the mean score. The following statements produce Output 28.2.1 through Output 28.2.3:

   title 'Dumping Syndrome Data';
   proc catmod data=operate order=data ;
      weight wt;
      response 0  0.5  1;
      model Severity=Treatment Hospital / freq oneway design;
      title2 'Main-Effects Model';
   quit;

The ORDER= option is specified so that the levels of the response variable remain in the correct order. A main-effects model is fit. The ONEWAY option produces a table of the number of subjects within each variable level, and the FREQ option displays the frequency of each response within each sample (Output 28.2.1).

Output 28.2.1 Surgical Data: Analysis of Mean Scores

Dumping Syndrome Data

Main-Effects Model

The CATMOD Procedure

Data Summary
Response	Severity	Response Levels	3
Weight Variable	wt	Populations	16
Data Set	OPERATE	Total Frequency	417
Frequency Missing	0	Observations	48

One-Way Frequencies
Variable	Value	Frequency
Severity	none	240
	slight	129
	moderate	48
Treatment	a	96
	b	104
	c	110
	d	107
Hospital	1	148
	2	105
	3	74
	4	90

Population Profiles
Sample	Treatment	Hospital	Sample Size
1	a	1	32
2	a	2	25
3	a	3	17
4	a	4	22
5	b	1	38
6	b	2	26
7	b	3	20
8	b	4	20
9	c	1	38
10	c	2	28
11	c	3	19
12	c	4	25
13	d	1	40
14	d	2	26
15	d	3	18
16	d	4	23

Response Profiles
Response	Severity
1	none
2	slight
3	moderate

Response Frequencies
Sample	Response Number
Sample	1	2	3
1	23	7	2
2	18	6	1
3	8	6	3
4	12	9	1
5	23	10	5
6	18	6	2
7	12	4	4
8	15	3	2
9	20	13	5
10	13	13	2
11	11	6	2
12	14	8	3
13	24	10	6
14	9	15	2
15	7	7	4
16	13	6	4

You can use the one-way frequencies and the response profiles from Output 28.2.1 to verify that the response levels are in the desired order (none, slight, moderate) so that the response scores (0, 0.5, 1.0) are applied appropriately. If the ORDER=DATA option had not been used, the levels would have been in a different order.

The analysis of variance table (Output 28.2.2) shows that the additive model fits (since the residual chi-square is not significant), that the Treatment effect is significant, and that the Hospital effect is not significant.

Output 28.2.2 Surgical Data: Analysis of Mean Scores

Response Functions and Design Matrix
Sample	Response Function	Design Matrix
Sample	Response Function	1	2	3	4	5	6	7
1	0.17188	1	1	0	0	1	0	0
2	0.16000	1	1	0	0	0	1	0
3	0.35294	1	1	0	0	0	0	1
4	0.25000	1	1	0	0	-1	-1	-1
5	0.26316	1	0	1	0	1	0	0
6	0.19231	1	0	1	0	0	1	0
7	0.30000	1	0	1	0	0	0	1
8	0.17500	1	0	1	0	-1	-1	-1
9	0.30263	1	0	0	1	1	0	0
10	0.30357	1	0	0	1	0	1	0
11	0.26316	1	0	0	1	0	0	1
12	0.28000	1	0	0	1	-1	-1	-1
13	0.27500	1	-1	-1	-1	1	0	0
14	0.36538	1	-1	-1	-1	0	1	0
15	0.41667	1	-1	-1	-1	0	0	1
16	0.30435	1	-1	-1	-1	-1	-1	-1

Analysis of Variance
Source	DF	Chi-Square	Pr > ChiSq
Intercept	1	248.77	<.0001
Treatment	3	8.90	0.0307
Hospital	3	2.33	0.5065
Residual	9	6.33	0.7069

The coefficients of Treatment in Output 28.2.3 show that the first two treatments (with negative coefficients) have lower mean scores than the last two treatments (the fourth coefficient, not shown, must be positive since the four coefficients must sum to zero). In other words, the less severe treatments (the first two) cause significantly less severe dumping syndrome complications.

Output 28.2.3 Surgical Data: Analysis of Mean Scores

Analysis of Weighted Least Squares Estimates
Parameter		Estimate	Standard Error	Chi- Square	Pr > ChiSq
Intercept		0.2724	0.0173	248.77	<.0001
Treatment	a	-0.0552	0.0270	4.17	0.0411
	b	-0.0365	0.0289	1.59	0.2073
	c	0.0248	0.0280	0.78	0.3757
Hospital	1	-0.0204	0.0264	0.60	0.4388
	2	-0.0178	0.0268	0.44	0.5055
	3	0.0531	0.0352	2.28	0.1312

Top of Page