This example is an illustration of a Weibull regression model that uses a load accelerated life test of rolling bearings, with data provided by Nelson (1990, p. 305) . Bearings are tested at four different loads, and lifetimes in of revolutions are measured. The data are shown in Table 14.3. An outlier identified by Nelson (1990) is omitted.

These data are modeled with a Weibull regression model in which the independent variable is the logarithm of the load. The model is

where is the location parameter of the extreme value distribution and

for the th bearing. The following statements create a SAS data set containing the loads, log loads, and bearing lifetimes:

data bearing;                                             
   input load Life @@;                                    
   lload = log(load);                                     
   datalines;                                             
 .87 1.67    .87 2.2    .87 2.51    .87 3.0    .87 3.9    
 .87 4.7     .87 7.53   .87 14.7    .87 27.76  .87 37.4   
 .99  .8     .99 1.0    .99 1.37    .99 2.25   .99 2.95   
 .99 3.7     .99 6.07   .99 6.65    .99 7.05   .99 7.37   
1.09  .18   1.09  .2   1.09  .24   1.09  .26  1.09  .32   
1.09  .32   1.09  .42  1.09  .44   1.09  .88  1.18  .073  
1.18  .098  1.18  .117 1.18  .135  1.18  .175 1.18  .262  
1.18  .270  1.18  .350 1.18  .386  1.18  .456             
;                                                         

Figure 14.17 shows a listing of the bearing data.

ods output modobstats = Residual;
proc reliability data=bearing;
   distribution weibull;
   model life = lload /  covb
                         corrb
                         obstats
                         ;
run;

The PROC RELIABILITY statement invokes the procedure and identifies BEARING as the input data set. The DISTRIBUTION statement specifies the Weibull distribution for model fitting. The MODEL statement specifies the regression model, identifying Life as the variable that provides the response values (the lifetimes) and Lload as the independent variable (the log loads). The MODEL statement option COVB requests the regression parameter covariance matrix, and the CORRB option requests the correlation matrix. The option OBSTATS requests a table that contains residuals, predicted values, and other statistics. The ODS OUTPUT statement creates a SAS data set named RESIDUAL that contains the table created by the OBSTATS option.

Figure 14.18 shows the tabular output produced by the RELIABILITY procedure. The "Weibull Parameter Estimates" table contains parameter estimates, their standard errors, and 95% confidence intervals. In this table, INTERCEPT corresponds to , LLOAD corresponds to , and SHAPE corresponds to the Weibull shape parameter. Figure 14.19 shows a listing of the output data set RESIDUAL.

The value of the lifetime Life and the log load Lload are included in this data set, as well as statistics computed from the fitted model. The variable Xbeta is the value of the linear predictor

for each observation. The variable Surv contains the value of the reliability function, the variable Sresid contains the standardized residual, and the variable Aresid contains a residual adjusted for right-censored observations. Since there are no censored values in these data, Sresid is equal to Aresid for all the bearings. See Table 14.28 and Table 14.29 for other statistics that are available in the OBSTATS table and data set. See the section Regression Model Statistics Computed for Each Observation for a description of the residuals and other statistics.

If the fitted regression model is adequate, the standardized residuals have a standard extreme value distribution. You can check the residuals by using the RELIABILITY procedure and the RESIDUAL data set to create an extreme value probability plot of the residuals.

The following statements create the plot in Figure 14.20:

proc reliability data=residual;
   distribution ev;
   probplot sresid;
run;

Figure 14.20 Extreme Value Probability Plot for the Standardized Residuals

Although the estimated location is near zero and the estimated scale is near one, the plot reveals systematic curvature, indicating that the Weibull regression model might be inadequate.