Saving Control Limits

[See SHWUCHR in the SAS/QC Sample Library]You can save the control limits for a chart in a SAS data set; this enables you to apply the control limits to future data (see Reading Preestablished Control Limits) or modify the limits with a DATA step program.

The following statements read defect counts from the data set Fabric (see Creating u Charts from Defect Count Data) and save the control limits displayed in Figure 13.30.4 in a data set named Fablim:

proc shewhart data=Fabric;
   uchart Defects*Roll / subgroupn = 30
                         outlimits = Fablim
                         nochart;
run;

The SUBGROUPN= option specifies the number of inspection units in each subgroup sample. The OUTLIMITS= option names the data set containing the control limits, and the NOCHART option suppresses the display of the chart. The data set Fablim is listed in Figure 13.30.5.

The data set Fablim contains one observation with the limits for process Defects. The variables _LCLU_ and _UCLU_ contain the lower and upper control limits, and the variable _U_ contains the central line. The value of _LIMITN_ is the nominal sample size associated with the control limits, and the value of _SIGMAS_ is the multiple of associated with the control limits. The variables _VAR_ and _SUBGRP_ are bookkeeping variables that save the process and subgroup-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the value of _U_ is an estimate or standard value. For more information, see OUTLIMITS= Data Set.

Alternatively, you can use the OUTTABLE= option to create an output data set that saves both the control limits and the subgroup statistics, as illustrated by the following statements:

proc shewhart data=Fabric;
   uchart Defects*Roll / subgroupn = 30
                         outtable  = Fabtab
                         nochart;
run;

The data set Fabtab is listed in Figure 13.30.6.

This data set contains one observation for each subgroup sample. The variables _SUBU_ and _SUBN_ contain the number of nonconformities per unit in each subgroup and the number of inspection units per subgroup. The variables _LCLU_ and _UCLU_ contain the lower and upper control limits, and the variable _U_ contains the central line. The variables _VAR_ and Roll contain the process name and values of the subgroup-variable, respectively. For more information, see OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set by the SHEWHART procedure. For example, the following statements read Fabtab and display a chart (not shown here) identical to the chart in Figure 13.30.4:

title 'u Chart for Fabric Defects';
proc shewhart Table=Fabtab;
   uchart Defects*Roll / subgroupn=30;
run;

Because the SHEWHART procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized control charts (see Specialized Control Charts). For more information, see TABLE= Data Set.