Saving Control Limits

[See SHWPCHR in the SAS/QC Sample Library]You can save the control limits for a chart in a SAS data set; this enables you to apply the control limits to future data (see Reading Preestablished Control Limits) or modify the limits with a DATA step program.

The following statements read the number of nonconforming items per subgroup from the data set Circuits (see Creating p Charts from Count Data) and save the control limits displayed in Figure 13.21.4 in a data set named Cirlim:

proc shewhart data=Circuits;
   pchart Fail*Batch / subgroupn = 500
                       outlimits = Cirlim
                       nochart ;
run;

The OUTLIMITS= option names the data set containing the control limits, and the NOCHART option suppresses the display of the chart. The data set Cirlim is listed in Figure 13.21.9.

The data set Cirlim contains one observation with the limits for process Fail. The variables _LCLP_ and _UCLP_ contain the lower and upper control limits, and the variable _P_ contains the central line. The value of _LIMITN_ is the nominal sample size associated with the control limits, and the value of _SIGMAS_ is the multiple of associated with the control limits. The variables _VAR_ and _SUBGRP_ are bookkeeping variables that save the process and subgroup-variable. The variable _TYPE_ is a bookkeeping variable that indicates whether the value of _P_ is an estimate or standard value.

For more information, see OUTLIMITS= Data Set.

You can create an output data set containing both control limits and summary statistics with the OUTTABLE= option, as illustrated by the following statements:

proc shewhart data=Circuits;
   pchart Fail*Batch / subgroupn = 500
                       outtable  = Cirtable
                       nochart ;
run;

The data set Cirtable is listed in Figure 13.21.10.

This data set contains one observation for each subgroup sample. The variables _SUBP_ and _SUBN_ contain the subgroup proportions of nonconforming items and subgroup sample sizes. The variables _LCLP_ and _UCLP_ contain the lower and upper control limits, and the variable _P_ contains the central line. The variables _VAR_ and Batch contain the process name and values of the subgroup-variable, respectively. For more information, see OUTTABLE= Data Set.

An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read the information in Cirtable and display a chart (not shown here) identical to the chart in Figure 13.21.4:

title 'p Chart for the Proportion of Failing Circuits';
proc shewhart table=Cirtable;
   pchart Fail*Batch;
run;

Because the SHEWHART procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized control charts (see Specialized Control Charts). For more information, see TABLE= Data Set.