###
Example 3.10 Cochran’s Q Test

When a binary response is measured several times or under different conditions, Cochran’s Q tests that the marginal probability of a positive response is unchanged across the times or conditions. When there are more
than two response categories, you can use the CATMOD procedure to fit a repeated-measures model.

The data set `Drugs`

contains data for a study of three drugs to treat a chronic disease (Agresti, 2002). Forty-six subjects receive drugs A, B, and C. The response to each drug is either favorable ('F') or unfavorable ('U').

proc format;
value $ResponseFmt 'F'='Favorable'
'U'='Unfavorable';
run;

data drugs;
input Drug_A $ Drug_B $ Drug_C $ Count @@;
datalines;
F F F 6 U F F 2
F F U 16 U F U 4
F U F 2 U U F 6
F U U 4 U U U 6
;

The following statements create one-way frequency tables of the responses to each drug. The AGREE option produces Cochran’s
Q and other measures of agreement for the three-way table. These statements produce Output 3.10.1 through Output 3.10.5.

proc freq data=Drugs;
tables Drug_A Drug_B Drug_C / nocum;
tables Drug_A*Drug_B*Drug_C / agree noprint;
format Drug_A Drug_B Drug_C $ResponseFmt.;
weight Count;
title 'Study of Three Drug Treatments for a Chronic Disease';
run;

The one-way frequency tables in Output 3.10.1 provide the marginal response for each drug. For drugs A and B, 61% of the subjects reported a favorable response while 35%
of the subjects reported a favorable response to drug C. Output 3.10.2 and Output 3.10.3 display measures of agreement for the 'Favorable' and 'Unfavorable' levels of drug A, respectively. McNemar’s test shows
a strong discordance between drugs B and C when the response to drug A is favorable.

Output 3.10.1: One-Way Frequency Tables

Output 3.10.2: Measures of Agreement for Drug A Favorable

-0.0328 |

0.1167 |

-0.2615 |

0.1960 |

Output 3.10.3: Measures of Agreement for Drug A Unfavorable

-0.1538 |

0.2230 |

-0.5909 |

0.2832 |

Output 3.10.4 displays the overall kappa coefficient. The small negative value of kappa indicates no agreement between drug B response
and drug C response.

Output 3.10.4: Overall Measures of Agreement

-0.0588 |

0.1034 |

-0.2615 |

0.1439 |

Cochran’s Q is statistically significant (p=0.0145 in Output 3.10.5), which leads to rejection of the hypothesis that the probability of favorable response is the same for the three drugs.

Output 3.10.5: Cochran’s Q Test