Functions and CALL Routines

ANYPUNCT Function

Searches a character string for a punctuation character, and returns the first position at which that character is found.

Category:	Character
Restriction:	I18N Level 2

Syntax
Arguments
Details
Comparisons
Examples
	Example 1: Searching a String for Punctuation Characters
	Example 2: Identifying Control Characters by Using the ANYPUNCT Function
See Also

Syntax

ANYPUNCT(string <,start>)

Arguments

string: is the character constant, variable, or expression to search.
start: is an optional integer that specifies the position at which the search should start and the direction in which to search.

Details

The results of the ANYPUNCT function depend directly on the translation table that is in effect (see TRANTAB System Option) and indirectly on the ENCODING System Option and the LOCALE System Option in SAS National Language Support (NLS): Reference Guide.

The ANYPUNCT function searches a string for the first occurrence of a punctuation character. If such a character is found, ANYPUNCT returns the position in the string of that character. If no such character is found, ANYPUNCT returns a value of 0.

If you use only one argument, ANYPUNCT begins the search at the beginning of the string. If you use two arguments, the absolute value of the second argument, start, specifies the position at which to begin the search. The direction in which to search is determined in the following way:

If the value of start is positive, the search proceeds to the right.
If the value of start is negative, the search proceeds to the left.
If the value of start is less than the negative length of the string, the search begins at the end of the string.

ANYPUNCT returns a value of zero when one of the following is true:

The character that you are searching for is not found.
The value of start is greater than the length of the string.
The value of start = 0.

Comparisons

The ANYPUNCT function searches a character string for a punctuation character. The NOTPUNCT function searches a character string for a character that is not a punctuation character.

Examples

Example 1: Searching a String for Punctuation Characters

The following example uses the ANYPUNCT function to search a string for punctuation characters.

data _null_;    
   string='Next = _n_ + 12E3;';  
   j=0;  
   do until(j=0);  
      j=anypunct(string,j+1);  
      if j=0 then put +3 "That's all";  
      else do;          
         c=substr(string,j,1);  
         put +3 j= c=;  
      end; 
   end;
run;

The following lines are written to the SAS log:

   j=6 c==
   j=8 c=_
   j=10 c=_
   j=12 c=+
   j=18 c=;
   That's all

Example 2: Identifying Control Characters by Using the ANYPUNCT Function

You can execute the following program to show the control characters that are identified by the ANYPUNCT function.

data test; 
do dec=0 to 255;
   byte=byte(dec);
   hex=put(dec,hex2.);
   anypunct=anypunct(byte);
   output;
 end;

 proc print data=test;
 run;