Example Program and Statement Details

data MSevents;
  input Date date9. Release $5.;
  label Release="Windows Release";
datalines;
01jun1990 3.0
01sep1995 95
01jul1998 98
01mar2000 2000
01nov2001 XP
run;

proc sort data=sashelp.stocks(keep=date stock close)
  out=MSstock;
  where stock="Microsoft"; 
  by date;
run;

data events(drop=temp); 
  retain temp; 
  merge MSstock MSevents(in=r);
  by date; 
  if first.date and r then temp=release;
  release=temp; 
run;

proc template;
  define statgraph blockplot1;
    begingraph;
      entrytitle "Microsoft Share Prices";
      entrytitle "and Significant OS Releases";
       layout overlay; 
         blockplot x=date block=release /
           datatransparency=.3 valuevalign=top
           labelposition=top display=(fill values label);
        seriesplot x=date y=close;
      endlayout;
    endgraph;
  end;
run;

proc sgrender data=events template=blockplot1;
run;

proc template;
  define statgraph blockplot2;
    begingraph;
      entrytitle "Microsoft Share Prices"; 
      entrytitle "and Significant OS Releases"; 
      layout lattice / rowweights=(.04 .96); 
        blockplot x=date block=release / datatransparency=.3
          valuefitpolicy=shrink  labelposition=left 
          display=(fill label outline values);
        seriesplot x=date y=close;
      endlayout;
    endgraph;
  end;
run; 

proc sgrender data=events template=blockplot2;
run;