The VARMAX Procedure

PROC VARMAX Statement

Other Options

PROC VARMAX options ;

The following options can be used in the PROC VARMAX statement:

DATA=SAS-data-set

specifies the input SAS data set. If the DATA= option is not specified, the PROC VARMAX statement uses the most recently created SAS data set.

OUTEST=SAS-data-set

writes the parameter estimates to the output data set.

COVOUT OUTCOV

writes the covariance matrix for the parameter estimates to the OUTEST= data set. This option is valid only if the OUTEST= option is specified.

OUTSTAT=SAS-data-set

writes residual diagnostic results to an output data set. If the COINTTEST=(JOHANSEN) option is specified, the results of this option are also written to the output data set.

The following statements are the examples of these options in the PROC VARMAX statement:

   proc varmax data=one outest=est outcov outstat=stat;
      model y1-y3 / p=1;
   run;

   proc varmax data=one outest=est outstat=stat;
      model y1-y3 / p=1 cointtest=(johansen);
   run;

PLOTS<(global-plot-option)> = plot-request-option <(options)> PLOTS<(global-plot-option)> = ( plot-request-option <(options)> ... plot-request-option <(options)> )

controls the plots produced through ODS Graphics. When you specify only one plot, you can omit the parentheses around the plot request. Some examples follow:

plots=none
plots=all
plots(unpack)=residual(residual normal)
plots=(forecasts model)

For general information about ODS Graphics, see Chapter 21: Statistical Graphics Using ODS in SAS/STAT 12.3 User's Guide.

proc varmax data=one plots=impulse(simple);
   model y1-y3 / p=1;
run;

proc varmax data=one plots=(model residual);
   model y1-y3 / p=1;
run;

proc varmax data=one plots=forecasts;
   model y1-y3 / p=1;
   output lead=12;
run;

The first VARMAX program produces the simple response impulse plots. The second VARMAX program produces the plots associated with the model and prediction errors. The plots associated with prediction errors are the ACF, PACF, IACF, distribution, white-noise, and Normal quantile plots and the prediction error plot. The third VARMAX program produces the FORECASTS and FORECASTSONLY plots.

The global-plot-option applies to the impulse and prediction error analysis plots generated by the VARMAX procedure. The following global-plot-option is available:

UNPACK: displays each graph separately. (By default, some graphs can appear together in a single panel.)

The following plot-request-options are available:

ALL

produces all plots appropriate for the particular analysis.

FORECASTS <(forecasts-plot-options )>

produces plots of the forecasts. The forecasts-only plot that shows the multistep forecasts in the forecast region is produced by default. The following forecasts-plot-options are available:

ALL: produces the FORECASTSONLY and the FORECASTS plots. This is the default.
FORECASTS: produces a plot that shows the one-step-ahead as well as the multistep forecasts.
FORECASTSONLY: produces a plot that shows only the multistep forecasts.

IMPULSE <(impulse-plot-options )>

produces the plots of impulse response function and the impulse response of the transfer function.

ALL: produces all impulse plots. This is the default.
ACCUM: produces the accumulated impulse plot.
ORTH: produces the orthogonalized impulse plot.
SIMPLE: produces the simple impulse plot.

MODEL

produces plots of dependent variables listed in the MODEL statement and plots of the one-step-ahead predicted values for each dependent variables.

NONE

suppresses all plots.

RESIDUAL <(residual-plot-options )>

produces plots associated with the prediction errors obtained after modeling the data. The following residual-plot-options are available:

ALL

produces all plots associated with the analysis of the prediction errors. This is the default.

RESIDUAL

produces prediction error plot.

DIAGNOSTICS

produces a panel of plots useful in assessing the autocorrelations and white-noise of the prediction errors. The panel consists of the following:

the autocorrelation plot of the prediction errors
the partial autocorrelation plot of the prediction errors
the inverse autocorrelation plot of the prediction errors
the log scaled white noise plot of the prediction errors

NORMAL

produces a panel of plots useful in assessing normality of the prediction errors. The panel consists of the following:

distribution of the prediction errors with overlaid the normal curve
normal quantile plot of the prediction errors

Other Options

In addition, any of the following MODEL statement options can be specified in the PROC VARMAX statement, which is equivalent to specifying the option for every MODEL statement: CENTER, DFTEST=, DIF=, DIFX=, DIFY=, LAGMAX=, METHOD=, MINIC=, NOCURRENTX, NOINT, NOPRINT, NSEASON=, P=, PRINT=, PRINTALL, PRINTFORM=, Q=, SCENTER, TREND=, VARDEF=, and XLAG= options.

The following is an example of the options in the PROC VARMAX statement:

   proc varmax data=one lagmax=3 method=ml;
      model y1-y3 / p=1;
   run;