The MDC procedure is similar in use to the other regression model procedures in the SAS System. However, the MDC procedure requires identification and choice variables. For example, consider a random utility function

where the cumulative distribution function of the stochastic component is type I extreme value, . You can estimate this conditional logit model with the following statements:

   proc mdc;
      model decision = x1 x2 / type=clogit
         choice=(mode 1 2 3);
      id pid;
   run;

Note that the MDC procedure, unlike other regression procedures, does not include the intercept term automatically. The dependent variable decision takes the value 1 when a specific alternative is chosen; otherwise it takes the value 0. Each individual is allowed to choose one and only one of the possible alternatives. In other words, the variable decision takes the value 1 one time only for each individual. If each individual has three elements (1, 2, and 3) in the choice set, the NCHOICE=3 option can be specified instead of CHOICE=(mode 1 2 3).

Consider the following trinomial data from Daganzo (1979). The original data (origdata ) contain travel time (ttime1-ttime3 ) and choice (choice ) variables. ttime1-ttime3 are the travel times for three different modes of transportation, and choice indicates which one of the three modes is chosen. The choice variable must have integer values.

   data origdata;
      input ttime1 ttime2 ttime3 choice @@;
   datalines;
   16.481  16.196  23.89   2  15.123  11.373  14.182  2
   19.469  8.822   20.819  2  18.847  15.649  21.28   2
   12.578  10.671  18.335  2  11.513  20.582  27.838  1
   
   ... more lines ...   

A new data set (newdata) is created since PROC MDC requires that each individual decision maker has one case for each alternative in his choice set. Note that the ID statement is required for all MDC models. In the following example, there are two public transportation modes, 1 and 2, and one private transportation mode, 3, and all individuals share the same choice set.

The first nine observations of the raw data set are shown in Figure 17.1.

The following statements transform the data according to MDC procedure requirements.

   data newdata(keep=pid decision mode ttime);
      set origdata;
      array tvec{3} ttime1 - ttime3;
      retain pid 0;
      pid + 1;
      do i = 1 to 3;
         mode = i;
         ttime = tvec{i};
         decision = ( choice = i );
         output;
      end;
   run;

The first nine observations of the transformed data set are shown in Figure 17.2.

The decision variable, decision, must have one nonzero value for each decision maker corresponding to the actual choice. When the RANK option is specified, the decision variable must contain rank data. For more details, see the section MODEL Statement. The following SAS statements estimate the conditional logit model by using maximum likelihood:

   proc mdc data=newdata;
      model decision = ttime /
               type=clogit
               nchoice=3
               optmethod=qn
               covest=hess;
      id pid;
   run;

The MDC procedure enables different individuals to face different choice sets. When all individuals have the same choice set, the NCHOICE= option can be used instead of the CHOICE= option. However, the NCHOICE= option is not allowed when a nested logit model is estimated. When the NCHOICE= option is specified, the choices are generated as . For more flexible alternatives (e.g., 1 3 6 8), you need to use the CHOICE= option. The choice variable must have integer values.

The OPTMETHOD=QN option specifies the quasi-Newton optimization technique. The covariance matrix of the parameter estimates is obtained from the Hessian matrix since COVEST=HESS is specified. You can also specify COVEST=OP or COVEST=QML. See the section MODEL Statement for more details.

The MDC procedure produces a summary of model estimation displayed in Figure 17.3. Since there are multiple observations for each individual, the "Number of Cases" (150)—that is, the total number of choices faced by all individuals—is larger than the number of individuals, "Number of Observations" (50). Figure 17.4 shows the frequency distribution of the three choice alternatives. In this example, mode 2 is most frequently chosen.