Previous Page | Next Page

The LOAN Procedure

Example 16.5 Piggyback Loans

The piggyback loan is becoming a widely available alternative. Borrowers like to avoid the PMI (private mortgage insurance) required with loans where the borrower has a down payment of less than 20% of the price. The piggyback allows a secondary home equity loan to be packaged with a primary loan with less than 20% down payment. The secondary loan usually has a shorter life and higher interest rate. The interest paid on both loans are tax-deductible whereas PMI does not qualify for a tax deduction.

The following example compares a conventional fixed rate loan with 20% down as opposed to a piggyback loan: one primary fixed rate with 10% down payment and a secondary, home equity loan for 10% of the original price. All loans have monthly payments.

The conventional loan alternative is a 30-year loan with a fixed annual rate of 7.5%. The primary loan in the piggyback loan setup is also a 30-year loan with a fixed annual rate of 7.75%. The secondary loan is a 15-year loan with a fixed annual interest rate of 8.25%.

The comparison output for the two loans comprising the piggyback loan is aggregated using the TIMESERIES procedure with a minimum of specified options:

  • The INTERVAL= option requests that the data be aggregated into periods of length 5 years beginning on the 25th month, resulting in appropriately identified periods.

  • The ACC=TOTAL option specifies that the output should reflect accumulated totals as opposed to, say, averages.

  • The NOTSORTED option indicates that the input data set has not been sorted by the ID variable.

See Chapter 27, The TIMESERIES Procedure, for more information about this procedure.

Use the following statements to analyze the conventional loan, as well as the piggyback alternative, and compare them on the basis of their present worth of cost, outstanding balance, and interest payment amounts at the end of 5, 10, and 15 years into the loan life.

   title1 'LOAN: Piggyback loan example';
   title2 'LOAN: Conventional loan';
   proc loan start=2002:1 noprint;
      fixed price=200000 dp=40000 rate=7.5 life=360
            label='20 percent down: Conventional Fixed Rate' ;
      compare at=(60 120 180) pwofcost taxrate=30 marr=12
              breakpay breakint outcomp=comploans;
   title2 'LOAN: Piggyback: Primary Loan';
   proc loan start=2002:1 noprint;
      fixed amount=160000 dp=20000 rate=7.75 life=360
            label='Piggyback: Primary loan' out=loan1;
      compare at=(60 120 180 ) pwofcost taxrate=30 marr=12
             breakpay breakint outcomp=cloan1;
   title2 'LOAN: Piggyback: Secondary (Home Equity) Loan';
   proc loan start=2002:1 noprint;
      fixed amount=20000  rate=8.25 life=180
            label='Piggyback: Secondary (Home Equity) Loan' out=loan2;
      compare at=(60 120 180 ) pwofcost taxrate=30 marr=12
              breakpay breakint  outcomp=cloan2;
   data cloan12;
      set cloan1  cloan2;
   proc timeseries data=cloan12 out= totcomp ;
      id date interval=year5.25 acc=total notsorted;
      var payment interest pwofcost balance ;
   /*-- LOAN: Piggyback loan --*/
   proc print data=totcomp;
      format date monyy7.;
   data comploans;
      set comploans;
      drop type label;
   /*-- LOAN: Conventional Loan --*/
   proc print data=comploans;

The loan comparisons in Output 16.5.1 and Output 16.5.2 illustrate the after-tax comparison of the loans. The after-tax present value of cost for the piggyback loan is lower than the 20% down conventional fixed rate loan.

Output 16.5.1 Piggyback Loan
1 JAN2007 1340.29 67992.92 157157.41 167575.52
2 JAN2012 1340.29 129973.53 135556.98 149138.73
3 JAN2017 1339.66 183028.58 125285.77 121777.01

Output 16.5.2 Conventional Loan
1 JAN2007 1118.74 58512.54 160436.81 151388.14
2 JAN2012 1118.74 113121.41 140081.64 138872.61
3 JAN2017 1118.74 162056.97 130014.97 120683.77

Previous Page | Next Page | Top of Page