ASEXPORT Procedure

Example: Exporting from a DataFlux Authentication Server to a SAS Metadata Server

Features:

PROC ASEXPORT statement

MATCH SINGLETON statement

Details

This example demonstrates the following actions:

specify metadata values
create explicit singleton matches between these two domains
auto-match domains by name
add remaining unmatched domains
perform explicit user matching
auto-match users by FQLN
add remaining unmatched users
list everything for review
create an input file (per noforward) for PROC METADATA that we can review

Assign a file reference.The FILENAME statement assigns a libref to an external SAS library that contains a permanent SAS catalog.

filename asx 'C:\TableServer\asexport.xml';

Specify metadata values.

proc ASEXPORT meta=
              (
                 user='username' password='password'
                 server='localhost'
                 port=port_number
                 repos='repositoryID'
                 filter=(DOMAINS "*"
                         USERS   "*"
                         LOGINS  "Login[Domain/AuthenticationDomain
[@OutboundOnly='0']]")
              )
              as=
              (
                 server='localhost'
                 user='username'
                 pass='password'
                 port=port_number
                 filter=(DOMAINS "domain=(domain_names)"
                         USERS   "enabled=TRUE subject=(ADMUSER, 
Shared_Login_Manager, tsadm, 'USER%')"
                         LOGINS  "(login IDs for included domains)")
              )
              verbose
              tracefile='C:\TableServer\asexport.croc' traceloc=SQL 
traceflags='319'
              retain
              out=asx
              ;

Create explicit singleton matches between these two domains.

   match singleton DOMAIN / criteria="as.domains.name_n='LOCAL' and 
meta.domains.name_n='domain_name'" log;
   match singleton DOMAIN / criteria="as.domains.name_n='UNIX' and 
meta.domains.name_n='domain_name'" log;

Auto-match domains by name.

   match DOMAINS / log;

Add remaining unmatched domains.

   add DOMAINS / log;

Perform explicit user matching.Attempt at least one user that has a matching Login. Nothing should match.

   match singleton USER / criteria="as.users.name_n='SHARED_LOGIN_MANAGER' 
and meta.users.name_n='FEDERATION SERVER SHARED LOGIN MANAGER'" log;
   match singleton USER / criteria="as.users.name_n='USER1' and 
meta.users.name_n='TSADM'" log;
   match singleton USER / criteria="as.users.name_n='TSADM' and 
meta.users.name_n='TSADM'" log;

Auto-match users by FQLN.

   match USERS / log;

Add remaining unmatched users.

   add USERS / log;

List everything for review.

   list DOMAINS USERS;

Create an input file (per noforward) for proc METADATA that we can review.

   export / noforward noverbose;

End processing of PROC ASEXPORT.

quit;