Generalized Estimating Equations

A study of the effects of pollution on children produced the following data. The binary response indicates whether children exhibited symptoms during the period of study at ages 8, 9, 10, and 11. A logistic regression is fit to the data with the explanatory variables age, city of residence, and a passive smoking index. The correlations among the binary outcomes are modeled as exchangeable.

The following statements create the data set Children and fit a GEE model by using the GENMOD procedure.

data children;
  input id city$ @@;
  do i=1 to 4;
    input age smoke symptom @@;
    output;
  end;
  datalines;
1 steelcity   8 0 1  9 0 1  10 0 1  11 0 0
2 steelcity   8 2 1  9 2 1  10 2 1  11 1 0
3 steelcity   8 2 1  9 2 0  10 1 0  11 0 0
4 greenhills  8 0 0  9 1 1  10 1 1  11 0 0
5 steelcity   8 0 0  9 1 0  10 1 0  11 1 0
6 greenhills  8 0 1  9 0 0  10 0 0  11 0 1
7 steelcity   8 1 1  9 1 1  10 0 1  11 0 0
8 greenhills  8 1 0  9 1 0  10 1 0  11 2 0
9 greenhills  8 2 1  9 2 0  10 1 1  11 1 0
10 steelcity  8 0 0  9 0 0  10 0 0  11 1 0
11 steelcity  8 1 1  9 0 0  10 0 0  11 0 1
12 greenhills 8 0 0  9 0 0  10 0 0  11 0 0
13 steelcity  8 2 1  9 2 1  10 1 0  11 0 1
14 greenhills 8 0 1  9 0 1  10 0 0  11 0 0
15 steelcity  8 2 0  9 0 0  10 0 0  11 2 1
16 greenhills 8 1 0  9 1 0  10 0 0  11 1 0
17 greenhills 8 0 0  9 0 1  10 0 1  11 1 1
18 steelcity  8 1 1  9 2 1  10 0 0  11 1 0
19 steelcity  8 2 1  9 1 0  10 0 1  11 0 0
20 greenhills 8 0 0  9 0 1  10 0 1  11 0 0
21 steelcity  8 1 0  9 1 0  10 1 0  11 2 1
22 greenhills 8 0 1  9 0 1  10 0 0  11 0 0
23 steelcity  8 1 1  9 1 0  10 0 1  11 0 0
24 greenhills 8 1 0  9 1 1  10 1 1  11 2 1
25 greenhills 8 0 1  9 0 0  10 0 0  11 0 0
;
run;

proc genmod data=children;
  class id city smoke;
  model  symptom = city age smoke / dist=bin type3;
  repeated  subject=id / type=exch covb corrw;
  contrast 'Smoke=0 vs Smoke=1' smoke 1 -1 0;
run;

The REPEATED statement requests a GEE analysis. The SUBJECT=ID option identifies ID as the clustering variable, and the TYPE=EXCH option specifies an exchangeable correlation structure. The TYPE3 option in the MODEL statement requests Type III statistics for each effect in the model. The CONTRAST statement requests a test that compares the first and second levels of the SMOKE effect.

This example shows how you can use the GEE procedure to analyze longitudinal data that contain missing values. The data set is taken from a longitudinal study of women who used contraception during one year (Fitzmaurice, Laird, and Ware 2011). In this study, 1,151 women were randomly assigned to one of two treatments: 100 mg or 150 mg of depot medroxyprogesterone acetate (DMPA) at baseline and at three-month intervals. The response variable indicates the women’s amenorrhea status during the four consecutive three-month intervals. The question of interest is whether the treatment has an effect on the rate of amenorrhea over time. The example follows the analysis by Fitzmaurice, Laird, and Ware (2011).

The following statements create the data set Amenorrhea:

data Amenorrhea;
   input ID Dose Time Y@@;
   datalines;
   1     0       1     0
   1     0       2     .
   1     0       3     .
   1     0       4     .

   ... more lines ...

1150     1       4     1
1151     1       1     1
1151     1       2     1
1151     1       3     1
1151     1       4     1
;

The variables in the data are as follows:

To prepare for the analysis, two additional variables are created:

The following statements add these two variables to the data set:

data Amenorrhea;
   set Amenorrhea;
   by ID;
   Prevy=lag(Y);
   if first.id then Prevy=0;
   Time=Time-1;
   Ctime=Time;
run;

Suppose denotes the amenorrhea status of woman i at the jth visit, , and suppose denotes the average rate of high dosage. To explore whether the treatment has an effect on the rate of amenorrhea over time, consider the following marginal model:

Of the 1,151 women in this study, 576 are from the low-dose group, and 575 are from the high-dose group. In the low-dose group, 62.67% of the women completed the trial; in the high-dose group, 61.39% of the women completed this trial. Thus, both groups have substantial dropouts.

To obtain the weights for the weighted GEE analysis, consider the following logistic regression model for missingness:

The following statements use the observation-specific weighted GEE method and the specified response and missingness models to analyze the data:

ods graphics on;
proc gee data=Amenorrhea desc plots=histogram;
   class ID Ctime;
   missmodel Ctime Prevy Dose Dose*Prevy / type=obslevel;
   model Y = Time Dose Time*Time Dose*Time Dose*Time*Time / dist=bin;
   repeated subject=ID / within=Ctime corr=cs;
run;

The MODEL statement specifies logistic regression and the model effects. The DESCEND option in the PROC GEE statement models the probability that Y = 1.

The REPEATED statement requests GEE analysis. The SUBJECT=ID option specifies that the variable ID indexes the subjects. The CORR=CS option specifies the compound symmetric working correlation structure.

The MISSMODEL statement requests the weighted GEE analysis. It specifies the logistic regression model for missingness. Note that no response variable is needed in weighted GEE analysis to specify a missingness model because the response is completely determined by the response variable in the MODEL statement. Without the MISSMODEL statement, PROC GEE would use the standard GEE approach, the same approach that PROC GENMOD provides. The TYPE=OBSLEVEL option requests observation-specific weights.

Figure 1 shows the parameter estimates for the missingness model. The estimate of is –0.4514 with a p-value of 0.0053, which suggests that the possibility that a participant will drop out is related to her previous amenorrhea status. This suggests that the assumption of MAR is more appropriate than that of MCAR.

The classification variable Ctime has two levels whose estimates are equal to 0. One is the reference level Ctime = 3. The first level, Ctime = 0, also has an estimate of 0, because the first visit is always observed and the first level is never used in estimating the weights in the missing model.

Figure 2 displays the results of the weighted GEE analysis.

The estimate of (the parameter estimate for the Dose*Time interaction) is 0.4092, which indicates that the change of amenorrhea rate over time depends on the dose of DMPA. Specifically, for women in the low-dose group the amenorrhea rates at the four consecutive time intervals are 0.1830, 0.2764, 0.3928, and 0.5210, and for women in the high-dose group the amenorrhea rates are 0.1997, 0.3609, 0.4963, and 0.5701. In other words, the amenorrhea rate increases over time for both treatments, and the rates of increase are slightly different.

You can request subject-level weights by specifying the TYPE=SUBLEVEL option. The results (not shown here) from the subject-level weighted method are similar to the results from the observation-level weighted method. Both weighted GEE methods provide unbiased regression parameter estimates if the missingness model is specified correctly. Preisser, Lohman, and Rathouz (2002) note that the observation-level weighted GEE method produces more efficient estimates than the cluster-level weighted GEE method produces for incomplete longitudinal binary data.

Large weights can have impacts on the parameter estimates. Consequently, it is recommended that you check the distribution of the estimated weights. If there are large weights, you might consider trimming them by specifying the MAXWEIGHT= option in the MISSMODEL statement. Figure 3 shows that the estimated weights in this example range between 1 and 2.1, so no trimming is needed.