%VERIFY自動呼び出しマクロ

式に固有の最初の文字の位置を返します。

種類:	自動呼び出しマクロ
要件	MAUTOSOURCEシステムオプション

構文

必須引数

詳細

例

構文

%VERIFY(source, excerpt)

必須引数

source

excerptに存在しない文字を調べる対象となるテキストまたはテキスト式。

excerpt

テキストまたはテキスト式。このテキストは、sourceを調べるために%VERIFYが使用する一連の文字を定義します。

詳細

注: 自動呼び出しマクロは、SASが提供するライブラリに含まれています。このライブラリは、サイトにインストールされていないか、サイト固有のバージョンである場合があります。このマクロにアクセスできない場合、またはマクロがサイト固有のバージョンかどうか知りたい場合は、オンサイトのSASサポート担当者に問い合わせてください。詳細については、マクロの保存および再利用を参照してください。

%VERIFYは、excerptに存在しない、source内の最初の文字の位置を返します。sourceのすべての文字がexcerptに存在する場合、%VERIFYは0を返します。

例: 有効なファイル参照名のテスト

ISNAMEマクロは、文字列をチェックして、それが有効なファイル参照名かどうかを検証し、文字列が有効または無効である理由を説明するメッセージをSASログに出力します。

%macro isname(name);
    %let name=%upcase(&name);
    %if %length(&name)>8 %then
       %put &name: The fileref must be 8 characters or less.;
    %else %do;
       %let first=ABCDEFGHIJKLMNOPQRSTUVWXYZ_;
       %let all=&first.1234567890;
       %let chk_1st=%verify(%substr(&name,1,1),&first);
       %let chk_rest=%verify(&name,&all);
       %if &chk_rest>0 %then
          %put &name: The fileref cannot contain
              "%substr(&name,&chk_rest,1)".;
       %if &chk_1st>0 %then
          %put &name: The first character cannot be
              "%substr(&name,1,1)".;
       %if (&chk_1st or &chk_rest)=0  %then
          %put &name is a valid fileref.;
    %end;
 %mend isname;
%isname(file1)
%isname(1file)
%isname(filename1)
%isname(file$)

このプログラムを実行すると、次のメッセージがSASログに書き込まれます。

FILE1 is a valid fileref.1FILE:The first character cannot be "1".FILENAME1:The fileref must be 8 characters or less.FILE$:The fileref cannot contain "$".