前のページ|次のページ

FILENAMEステートメント、CLIPBOARDアクセス方式

ホストコンピュータ上のクリップボードに対して、テキストデータを読み込み、書き込みできます。

該当要素: 任意の場所
カテゴリ: データアクセス

構文

引数

fileref

有効なファイル参照名を指定します。

CLIPBRD

このアクセス方式を指定すると、ホストコンピュータ上のクリップボードに対してデータを読み込み、書き込みできます。

BUFFER=paste-buffer-name

貼り付けバッファの名前を指定すると、指定した名前で貼り付けバッファが作成されます。STOREコマンドでBUFFER=引数を使用して貼り付けバッファの名前を指定すると、任意の数の貼り付けバッファを作成できます。

詳細

FILENAMEステートメントでCLIPBOARDアクセス方式を使用すると、SAS内や、SASと非SASアプリケーション間でデータを共有できます。

比較

STOREコマンドでは、現在のウィンドウでマークされたテキストをコピーし、コピーしたテキストを貼り付けバッファに格納します。
エクスプローラのポップアップメニューからコンテンツをクリップボードにコピーを選択して、データをクリップボードにコピーすることもできます。

例1: ODSを使用してデータセットをHTML形式でクリップボードに書き込む

この例では、入力ファイルとしてSashelp.Airデータセットを使用します。このデータセットをHTML形式でクリップボードに書き込むためにODSが使用されます。
filename _temp_ clipbrd;
   ods noresults;
   ods html file=_temp_ rs=none style=minimal;
   proc print data=Sashelp.'Air'N noobs;
run;
ods results;
filename _temp_;

例2: DATAステップを使用してデータセットをカンマ区切りの値としてクリップボードに書き込む

この例では、入力ファイルとしてSashelp.Airデータセットを使用します。DATAステップ内のデータがカンマ区切りの値としてクリップボードに書き込まれます。
filename _temp1_ temp;
filename _temp2_ clipbrd;
proc contents data=Sashelp."Air"N out=info noprint;
proc sort data=info;
   by npos;
run;
data _null_;
   set info end=eof;
   ;
   file _temp1_ dsd;
   put name @@;
   if _n_=1 then do;
      call execute("data _null_;
      set Sashelp.""Air""N; 
      file _temp1_ dsd mod; 
      put");
   end;
   call execute(trim(name));
   if eof then call execute('; run;');
run;
data _null_;
   infile _temp1_;
   file _temp2_;
   input;
   put _infile_;
run;
filename _temp1_ clear;
filename _temp2_ clear;

例3: DATAステップを使用してテキストをクリップボードに書き込む

この例では、クリップボードに3行書き込みます
filename clippy clipbrd;
data _null_;
   file clippy;
   put 'Line 1';
   put 'Line 2';
   put 'Line 3';
run;

例4: DATAステップを使用してテキストをクリップボードから取得する

この例では、クリップボードに3行書き込んだ後、書き込んだデータを取得します。
filename clippy clipbrd;
data _null_;
   file clippy;
   put 'Line 1';
   put 'Line 2';
   put 'Line 3';
run;
data _null_;
   infile clippy;
   input;
   put _infile_;
run;

関連項目:

コマンド:
Base SAS Help and DocumentationのSTOREコマンド
前のページ|次のページ|ページの先頭へ