IORCMSG関数

_IORC_の書式化されたエラーメッセージを返します。

カテゴリ:

SASファイルI/O

構文

詳細

例

構文

IORCMSG()

詳細

まだ長さが割り当てられていない変数にIORCMSG関数から値が返される場合、変数にはデフォルトで長さ200が割り当てられます。

IORCMSG関数は、自動変数_IORC_の現在値に関連付けられた、書式化されたエラーメッセージを返します。_IORC_変数は、MODIFYステートメントを使用した場合、またはSETステートメントにKEY=オプションを使用した場合に作成されます。_IORC_変数の値は内部値で、SYSRC自動呼出しマクロと組み合わせて読み取られます。_IORC_に特定の値を設定しようとすると、予期しない結果になる可能性があります。

例

次のプログラムでは、銀行口座と現在の銀行預金残高を含む、更新されたマスタファイルにオブザベーションが再書き込みまたは追加されます。このプログラムは_IORC_変数をクエリし、_IORC_値が予期しない値の場合は書式化されたエラーメッセージを返します。

libname bank 'SAS-library';
data bank.master(index=(AccountNum));
   infile 'external-file-1';
   format balance dollar8.;
   input @ 1 AccountNum $ 1–3 @ 5 balance 5–9;
run;
data bank.trans(index=(AccountNum));
   infile 'external-file-2';
   format deposit dollar8.;
   input @ 1 AccountNum $ 1–3 @ 5 deposit 5–9;
run;
data bank.master;
   set bank.trans;
   modify bank.master key=AccountNum;  
   if (_IORC_ EQ %sysrc(_SOK)) then 
      do; 
         balance=balance+deposit; 
         replace;  
      end; 
else      
   if (_IORC_= %sysrc(_DSENOM)) then 
      do;
         balance=deposit;    
         output;  
         _error_=0; 
      end;   
else   
   do;   
      errmsg=IORCMSG();   
      put 'Unknown error condition:' 
      errmsg; 
   end; 
run;