The ROBUSTREG Procedure

Robust regression and outlier detection techniques have considerable applications to econometrics. This example, from Zaman, Rousseeuw, and Orhan (2001), shows how these techniques substantially improve the ordinary least squares (OLS) results for the growth study of De Long and Summers.

De Long and Summers (1991) studied the national growth of 61 countries from 1960 to 1985 by applying OLS to the following data set:

data growth;
   input country $ GDP LFG EQP NEQ GAP @@;
   datalines;
Argentin  0.0089 0.0118 0.0214 0.2286 0.6079
Austria   0.0332 0.0014 0.0991 0.1349 0.5809
Belgium   0.0256 0.0061 0.0684 0.1653 0.4109
Bolivia   0.0124 0.0209 0.0167 0.1133 0.8634
Botswana  0.0676 0.0239 0.1310 0.1490 0.9474

   ... more lines ...   

Venezuel  0.0120 0.0378 0.0340 0.0760 0.4974
Zambia   -0.0110 0.0275 0.0702 0.2012 0.8695
Zimbabwe  0.0110 0.0309 0.0843 0.1257 0.8875
;

The regression equation that they used is

where the response variable is the growth in gross domestic product per worker (GDP) and the regressors are labor force growth (LFG), relative GDP gap (GAP), equipment investment (EQP), and nonequipment investment (NEQ).

The following statements invoke the REG procedure (see Chapter 83: The REG Procedure) for the OLS analysis:

proc reg data=growth;
   model GDP  = LFG GAP EQP NEQ;
run;

The OLS analysis that is shown in Output 84.3.1 indicates that GAP and EQP have a significant influence on GDP at the 5% level.

The following statements invoke the ROBUSTREG procedure and use the default M estimation:

ods graphics on;

proc robustreg data=growth plots=all;
   model GDP  = LFG GAP EQP NEQ / diagnostics leverage;
   id country;
run;

ods graphics off;

Output 84.3.2 displays model information and summary statistics for variables in the model.

Output 84.3.3 displays the M estimates. Besides GAP and EQP, the robust analysis also indicates that NEQ is significant. This new finding is explained by Output 84.3.4, which shows that Zambia, the 60th country in the data, is an outlier. Output 84.3.4 also identifies leverage points that are based on the robust MCD distances; however, there are no serious high-leverage points in this data set.

Output 84.3.5 displays robust versions of goodness-of-fit statistics for the model.

The PLOTS=ALL option generates four diagnostic plots. Output 84.3.6 and Output 84.3.7 are for outlier and leverage-point diagnostics. Output 84.3.8 and Output 84.3.9 are a histogram and a Q-Q plot, respectively, of the standardized robust residuals.

The following statements invoke the ROBUSTREG procedure and use LTS estimation, which was used by Zaman, Rousseeuw, and Orhan (2001). The results are consistent with those of M estimation.

proc robustreg method=lts(h=33) fwls data=growth seed=100;
   model GDP  = LFG GAP EQP NEQ / diagnostics leverage;
   id country;
run;

Output 84.3.10 displays the LTS estimates and the LTS R square.

Output 84.3.11 displays outlier and leverage-point diagnostics that are based on the LTS estimates and the robust MCD distances.

Output 84.3.12 displays the final weighted least squares estimates, which are identical to those that are reported in Zaman, Rousseeuw, and Orhan (2001).