| The NETDRAW Procedure |
Example 7.1: Line-Printer Network Diagram
This example uses the data set WIDGET that was used in Example 2.2 in Chapter 2, "The CPM Procedure," to illustrate the Activity-on-Node representation of the project. The following program invokes PROC NETDRAW twice. First, the Activity data set WIDGET is used as input to the procedure. The activity and successor information is identified using the ACTIVITY= and SUCCESSOR= options in the ACTNET statement. The LINEPRINTER option is specified, producing the line-printer network diagram shown in Output 7.1.1.
/* Activity-on-Node representation of the project */
data widget;
format task $12. succ1-succ3 $12.;
input task & days succ1 & succ2 & succ3 & ;
datalines;
Approve Plan 5 Drawings Anal. Market Write Specs
Drawings 10 Prototype . .
Anal. Market 5 Mkt. Strat. . .
Write Specs 5 Prototype . .
Prototype 15 Materials Facility .
Mkt. Strat. 10 Test Market Marketing .
Materials 10 Init. Prod. . .
Facility 10 Init. Prod. . .
Init. Prod. 10 Test Market Marketing Evaluate
Evaluate 10 Changes . .
Test Market 15 Changes . .
Changes 5 Production . .
Production 0 . . .
Marketing 0 . . .
;
title 'Widget Manufacture';
options ps=32 ls=78;
proc netdraw data=widget lineprinter;
actnet / activity=task successor=(succ1 succ2 succ3);
run;
Output 7.1.1: Line-Printer Network Diagram
Next, PROC CPM is invoked to schedule the project, and the resulting Schedule data set is used as input to the NETDRAW procedure. In addition to the ACTIVITY= and SUCCESSOR= options, the DURATION= option is used in the ACTNET statement. The DURATION= option adds the values of the DURATION variable within each node of the network. The procedure also displays the values of the E_START, E_FINISH, L_START, L_FINISH, T_FLOAT, and F_FLOAT variables within each node. The network is displayed in Output 7.1.2.
proc cpm data=widget out=sched
date='1dec03'd;
activity task;
successor succ1 succ2 succ3;
duration days;
run;
options ps=45 ls=90;
title2 'Schedule Information';
proc netdraw data=sched lineprinter;
actnet / activity=task
successor=(succ1 succ2 succ3)
duration = days;
run;
Output 7.1.2: Project Schedule
|
Copyright © 2008 by SAS Institute Inc., Cary, NC, USA. All rights reserved.