The OPTNET Procedure

Consider a cross-country trip where you want to travel the fewest miles to visit all of the capital cities in all US states except Alaska and Hawaii. Finding the optimal route is an instance of the traveling salesman problem, which is described in section Traveling Salesman Problem.

The following PROC SQL statements use the built-in data set maps.uscity to generate a list of the capital cities and their latitude and longitude:

/* Get a list of the state capital cities (with lat and long) */
proc sql;
   create table Cities as
   select unique statecode as state, city, lat, long
      from maps.uscity 
      where capital='Y' and statecode not in ('AK' 'PR' 'HI');
quit;

From this list, you can generate a links data set CitiesDist that contains the distances, in miles, between each pair of cities. The distances are calculated by using the SAS function GEODIST.

/* Create a list of all the possible pairs of cities */
proc sql;
   create table CitiesDist as
   select 
      a.city as city1, a.lat as lat1, a.long as long1,
      b.city as city2, b.lat as lat2, b.long as long2,
      geodist(lat1, long1, lat2, long2, 'DM') as distance
      from Cities as a, Cities as b
      where a.city < b.city;
quit;

The following PROC OPTNET statements find the optimal tour through each of the capital cities:

/* Find optimal tour using OPTNET */
proc optnet 
   loglevel   = moderate
   data_links = CitiesDist 
   out_nodes  = TSPTourNodes;
   data_links_var 
      from    = city1 
      to      = city2 
      weight  = distance;
   tsp 
      out     = TSPTourLinks;
run;
%put &_OROPTNET_;
%put &_OROPTNET_TSP_;

The progress of the procedure is shown in Output 2.7.1. The total mileage needed to optimally traverse the capital cities is miles.

The following PROC GPROJECT and PROC GMAP statements produce a graphical display of the solution:

/* Merge latitude and longitude */
proc sql;
   /* merge in the lat & long for city1 */
   create table TSPTourLinksAnno1 as
   select unique TSPTourLinks.*, cities.lat as lat1, cities.long as long1
      from TSPTourLinks left join cities
      on TSPTourLinks.city1=cities.city;
   /* merge in the lat & long for city2 */
   create table TSPTourLinksAnno2 as
   select unique TSPTourLinksAnno1.*, cities.lat as lat2, cities.long as long2
      from TSPTourLinksAnno1 left join cities
      on TSPTourLinksAnno1.city2=cities.city;      
quit; 

/* Create the annotated data set to draw the path on the map 
    (convert lat & long degrees to radians, since the map is in radians) */
data anno_path; 
   set TSPTourLinksAnno2;
   length function color $8;
   xsys='2'; ysys='2'; hsys='3'; when='a'; anno_flag=1;
   function='move';
   x=atan(1)/45 * long1;
   y=atan(1)/45 * lat1;
   output;
   function='draw'; 
   color="blue"; size=0.8;
   x=atan(1)/45 * long2;
   y=atan(1)/45 * lat2;
   output;
run;

/* Get a map with only the contiguous 48 states */
data states; 
   set maps.states (where=(fipstate(state) not in ('HI' 'AK' 'PR')));
run;

data combined; 
   set states anno_path; 
run;

/* Project the map and annotate the data */
proc gproject data=combined out=combined dupok;
   id state;
run;

data states anno_path;
   set combined;
   if anno_flag=1 then output anno_path;
   else                output states;
run;

/* Get a list of the endpoints locations */
proc sql;
   create table anno_dots as
   select unique x, y from anno_path;
quit; 

/* Create the final annotate data set */
data anno_dots; 
   set anno_dots;
   length function color $8;
   xsys='2'; ysys='2'; when='a'; hsys='3'; 
   function='pie'; 
   rotate=360; size=0.8; style='psolid'; color="red"; 
   output;
   style='pempty'; color="black"; 
   output;
run;

/* Generate the map with GMAP */
pattern1 v=s c=cxccffcc repeat=100;
proc gmap data=states map=states anno=anno_path all;
   id state;
   choro state / levels=1 nolegend coutline=black 
                 anno=anno_dots des='' name="tsp";
run;

The minimal cost tour through the capital cities is shown on the US map in Output 2.7.2.

The data set TSPTourLinks contains the links in the optimal tour. To display the links in the order they are to be visited, you first sort by the optimal ordering that is defined in the data set TSPTourNodes, as follows:

/* Merge in the order, and sort by that order */
proc sql noprint;
   create table TSPTourLinksSort as
   select unique TSPTourLinks.*, TSPTourNodes.tsp_order
      from TSPTourLinks left join TSPTourNodes
      on TSPTourLinks.city1=TSPTourNodes.node
   order by tsp_order;
quit; 

The data set TSPTourLinks is shown in Output 2.7.3.