Example Program and Statement Details

proc template;
  define statgraph surfaceplotparm;
    begingraph;
      entrytitle "Surface Plot of Lake Bed";
      layout overlay3d / cube=false;
        surfaceplotparm x=length y=width z=depth /
          reversecolormodel=true
          surfacecolorgradient=depth
          colormodel=twocoloraltramp;
      endlayout;
    endgraph;
  end;

/* create gridded data for surface 
 * proc g3grid is a sas/graph procedure */
proc g3grid data=sashelp.lake out=gridded;
  grid width*length = depth / naxis1=75 naxis2=75;
run;

proc sgrender data= gridded template=surfaceplotparm;
run;

data nums;
  do i=1 to 30;
     X=10*ranuni(33)-5;
     Y=10*ranuni(35)-5;
     Z=sin(sqrt(x*x+y*y));
     output;
  end;
run; 
proc g3grid data=nums out=gridded;
  grid y*x=z / spline 
               axis1=-5 to 5 by .1
               axis2=-5 to 5 by .1;
run;
proc sort data=gridded; by y x; run;

proc template;
  define statgraph g3grid_surface; 
   begingraph;
    entrytitle "Spline Interpolation";
    layout overlay3d;
      surfaceplotparm x=x y=y z=z / 
        surfacetype=fill;
    endlayout; 
   endgraph;
  end;
run;

proc sgrender data=gridded template=g3grid_surface;
run;

/* use the nums data generated in the previous example */
proc kde data=nums;
  bivar x y / ngrid=100
    out=binned(rename=(value1=X value2=Y));
run;
proc sort data=binned; by y x;
  label x="X" y="Y";
run;

proc template;
  define statgraph kde_surface;
   begingraph;
     entrytitle "Kernel Density Estimate";
     layout overlay3d;
       surfaceplotparm x=x y=y z=density /
         surfacetype=fill;
     endlayout;
   endgraph;
  end;
run;

proc sgrender data=binned template=kde_surface;
run;