Previous Page

|

Next Page

The VARMAX Procedure

Example 30.2 Analysis of German Economic Variables

This example considers a three-dimensional VAR(2) model. The model contains the logarithms of a quarterly, seasonally adjusted West German fixed investment, disposable income, and consumption expenditures. The data used are in Lütkepohl (1993, Table E.1).

   title 'Analysis of German Economic Variables';
   data west;
      date = intnx( 'qtr', '01jan60'd, _n_-1 );
      format date yyq. ;
      input y1 y2 y3 @@;
      y1 = log(y1);
      y2 = log(y2);
      y3 = log(y3);
      label y1 = 'logarithm of investment'
            y2 = 'logarithm of income'
            y3 = 'logarithm of consumption';
   datalines;
   180  451  415 179  465  421 185  485  434 192  493  448
   
   ... more lines ...   

   data use;
      set west;
      where  date < '01jan79'd;
      keep date y1 y2 y3;
   run;

   proc varmax data=use;
      id date interval=qtr;
      model y1-y3 / p=2 dify=(1)
                    print=(decompose(6) impulse=(stderr) estimates diagnose)
                    printform=both lagmax=3;
      causal group1=(y1) group2=(y2 y3);
      output lead=5;
   run;

First, the differenced data is modeled as a VAR(2) with the following result:

The parameter estimates AR1_1_2, AR1_1_3, AR2_1_2, and AR2_1_3 are insignificant, and the VARX model is fitted in the next step.

The detailed output is shown in Output 30.2.1 through Output 30.2.8.

Output 30.2.1 shows the descriptive statistics.

Output 30.2.1 Descriptive Statistics

Analysis of German Economic Variables

The VARMAX Procedure

Number of Observations	75
Number of Pairwise Missing	0
Observation(s) eliminated by differencing	1

Simple Summary Statistics
Variable	Type	N	Mean	Standard Deviation	Min	Max	Difference	Label
y1	Dependent	75	0.01811	0.04680	-0.14018	0.19358	1	logarithm of investment
y2	Dependent	75	0.02071	0.01208	-0.02888	0.05023	1	logarithm of income
y3	Dependent	75	0.01987	0.01040	-0.01300	0.04483	1	logarithm of consumption

Output 30.2.2 shows that a VAR(2) model is fit to the data.

Output 30.2.3 shows the parameter estimates and their significance.

Output 30.2.4 shows the innovation covariance matrix estimates, the various information criteria results, and the tests for white noise residuals. The residuals are uncorrelated except at lag 3 for variable.

Output 30.2.5 describes how well each univariate equation fits the data. The residuals are off from the normality, but have no AR effects. The residuals for variable have the ARCH effect.

Output 30.2.6 is the output in a matrix format associated with the PRINT=(IMPULSE=) option for the impulse response function and standard errors. The variable in the first row is an impulse variable. The variable in the first column is a response variable. The numbers, 0.96122, 0.41555, –0.40789 at lag 1 to 3 are decreasing.

The proportions of decomposition of the prediction error covariances of three variables are given in Output 30.2.7. If you see the variable in the first column, then the output explains that about 64.713% of the one-step-ahead prediction error covariances of the variable is accounted for by its own innovations, about 7.995% is accounted for by innovations, and about 27.292% is accounted for by innovations.

The table in Output 30.2.8 gives forecasts and their prediction error covariances.

Output 30.2.9 shows that you cannot reject Granger noncausality from to using the 0.05 significance level.

The following SAS statements show that the variable is the exogenous variable and fit the VARX(2,1) model to the data.

   proc varmax data=use;
      id date interval=qtr;
      model y2 y3 = y1 / p=2 dify=(1) difx=(1) xlag=1 lagmax=3
                         print=(estimates diagnose);
   run;

The fitted VARX(2,1) model is written as

The detailed output is shown in Output 30.2.10 through Output 30.2.13.

Output 30.2.10 shows the parameter estimates in terms of the constant, the current and the lag one coefficients of the exogenous variable, and the lag two coefficients of the dependent variables.

Output 30.2.11 shows the parameter estimates and their significance.

Output 30.2.12 shows the innovation covariance matrix estimates, the various information criteria results, and the tests for white noise residuals. The residuals is uncorrelated except at lag 3 for variable.

Output 30.2.13 describes how well each univariate equation fits the data. The residuals are off from the normality, but have no ARCH and AR effects.

Copyright © 2008 by SAS Institute Inc., Cary, NC, USA. All rights reserved.