Example 14.1 Combining Monthly and Quarterly Data

This example combines monthly and quarterly data sets by interpolating monthly values for the quarterly series. The series are extracted from two small sample data sets stored in the SASHELP library. These data sets were contributed by Citicorp Data Base services and contain selected U.S. macro economic series.

The quarterly series gross domestic product (GDP) and implicit price deflator (GD) are extracted from SASHELP.CITIQTR. The monthly series industrial production index (IP) and unemployment rate (LHUR) are extracted from SASHELP.CITIMON. Only observations for the years 1990 and 1991 are selected. PROC EXPAND is then used to interpolate monthly estimates for the quarterly series, and the interpolated series are merged with the monthly data.

The following statements extract and print the quarterly data, shown in Output 14.1.1.

   data qtrly;
      set sashelp.citiqtr;
      where date >= '1jan1990'd &
            date <  '1jan1992'd ;
      keep date gdp gd;
   run;
   
   title "Quarterly Data";
   proc print data=qtrly;
   run;

The following statements extract and print the monthly data, shown in Output 14.1.2.

   data monthly;
      set sashelp.citimon;
      where date >= '1jan1990'd &
            date <  '1jan1992'd ;
      keep date ip lhur;
   run;
   
   title "Monthly Data";
   proc print data=monthly;
   run;

The following statements interpolate monthly estimates for the quarterly series and merge the interpolated series with the monthly data. The resulting combined data set is then printed, as shown in Output 14.1.3.

   proc expand data=qtrly out=temp from=qtr to=month;
      convert gdp gd / observed=average;
      id date;
   run;
   
   data combined;
      merge monthly temp;
      by date;
   run;
   
   title "Combined Data Set";
   proc print data=combined;
   run;