Example 7.3 Model for Series J Data from Box and Jenkins

This example uses the Series J data from Box and Jenkins (1976). First, the input series X is modeled with a univariate ARMA model. Next, the dependent series Y is cross-correlated with the input series. Since a model has been fit to X, both Y and X are prewhitened by this model before the sample cross-correlations are computed. Next, a transfer function model is fit with no structure on the noise term. The residuals from this model are analyzed; then, the full model, transfer function and noise, is fit to the data.

The following statements read 'Input Gas Rate' and 'Output CO' from a gas furnace. (Data values are not shown. The full example including data is in the SAS/ETS sample library.)

   title1 'Gas Furnace Data';
   title2 '(Box and Jenkins, Series J)';
   data seriesj;
      input x y @@;
      label x = 'Input Gas Rate'
            y = 'Output CO2';
   datalines;
   
   ... more lines ...   

The following statements produce Output 7.3.1 through Output 7.3.11:

   proc arima data=seriesj;
   
      /*--- Look at the input process -------------------*/
      identify var=x;
      run;
   
      /*--- Fit a model for the input -------------------*/
      estimate p=3 plot;
      run;
   
      /*--- Crosscorrelation of prewhitened series ------*/
      identify var=y crosscorr=(x) nlag=12;
      run;
      
      /*- Fit a simple transfer function - look at residuals -*/
      estimate input=( 3 $ (1,2)/(1) x );
      run;
   
      /*--- Final Model - look at residuals ---*/
      estimate p=2 input=( 3 $ (1,2)/(1) x );
      run;
   
   quit;

The results of the first IDENTIFY statement for the input series X are shown in Output 7.3.1. The correlation analysis suggests an AR(3) model.