To view the names of all of the style templates that are shipped with SAS®, the TEMPLATE procedure can be used with the LIST statement to display the names of all of the templates that are located in the SASHELP.TMPLMST item store. The style templates are all located in the Styles folder by default.

proc template;
   list styles;
run;

To visually view all of the styles shipped with SAS, you can use PROC TEMPLATE with the LIST statement and macro logic to dynamically build an HTML frame. See the code on the Full Code tab for an example.

An alternate method showing the styles applied to PDF and RTF output is shown on page 13 of the following paper: The Output Delivery System (ODS) from Scratch.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

%let path=c:\temp;  

%macro showstyle(style);

ods html path="&path"(url=none) file="&style..html" 
    contents=temp(notop nobot) frame="frame.html" style=&style;
ods proclabel "Style name";

proc print data=sashelp.class contents="Styles.&style";
run;

ods html close;

%mend;

ods path work.templat(update) sashelp.tmplmst(read);

filename temp "&path\contents.html" mod;
ods html path="&path"(url=none) contents=temp(nobot);
ods html exclude stats;

ods output stats=styles(where=(type ne "Dir"));

proc template;
   list styles;
run;

proc sort data=styles;
   by path;
run;

data one;
   set styles;
   by path;
   if first.path then
      call execute('%showstyle('||path||')');
run;

data _null_;
   file temp;
   put "</body>";
   put "</html>";
run;

ods path reset;

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

 Below is an image of how the frame will look.

>

Operating System and Release Information