If you create a user-defined format with PROC FORMAT and the format name
is an internal one that SAS supplies, you may not receive a note or
warning to that effect.

If you later apply the user-defined format to a variable, the SAS
supplied format may be used instead. This occurs for some formats.

For example, the SAS 9.1 log below shows the user-defined WEEK format
successfully created with no note or warning. When the format is later
referenced with the PUT statement, the SAS-supplied format is displayed.

   538  proc format;
   539     value week
   540       low-1  = "0"
   541       2-10   = "1";
   NOTE: Format WEEK has been output.

   543  data _null_;
   544    x=1;
   545    put x week.;
   546  run;

   1960-W00-07

The workaround is to change the name of the user-defined format. If you
have the original source code, you can simply change the name and rerun
the code to create the new format. If not, follow the instructions
below, including the final step that shows how to delete the duplicate
format.

To do this, the PROC FORMAT CNTLOUT= option is used to output a data
set.  Assign a new value to the variable FMTNAME, then recreate the
format with the PROC FORMAT CNTLIN= option. If you then want to clean up
the format catalog by removing the original format from the FORMAT
catalog, you can use the PROC CATALOG DELETE statement.

See the sample code for the workaround below.

     /* output selected entry to data set */

   proc format cntlout=newfmt;
     select week;
   run;

     /* Assign new format name */

   data newfmt;
     set newfmt;
     fmtname="SiteSpecificWeek";
   run;

     /* Create new format */

   proc format cntlin=newfmt ;
   run;

   /* Delete old format */

   proc catalog cat=work.formats;
   delete week.format;
   run;
   quit;

Operating System and Release Information