There are a number of procedures that you can use to find the top 1% and bottom 1% of data values, including PROC RANK, PROC SQL, and PROC UNIVARIATE. The example code below uses PROC SUMMARY and DATA step logic to create macro variables that contain the 1st and 99th percentile values. These macro variables can be used for further processing to subset the original data set.

/* Create sample data */
data test;                   
   do i=1 to 10000;                                                     
      x=ranuni(i)*12345;                                         
      output;                                                         
   end; 
   drop i; 
run;     

proc sort data=test;
   by x;
run; 
                                                                      
/* Output the 1st and 99th percentile values */                         
proc summary data=test;                                               
   var x;                                                       
   output out=test1 p1= p99= / autoname;                               
run;                                                                 
                                                                      
/* Create macro variables for the 1st and 99th percentile values  */     
data _null_;                                                         
   set test1;                                                         
   call symputx('p1', x_p1);                                     
   call symputx('p99',x_p99);                                     
run;    
%put &p1;
%put &p99; 
                                                                      
data test2;                                                             
   set test;                                                           
/* Use a WHERE statement to subset the data  */                         
   where &p1 le x le &p99;                                       
run;  

proc print;
run; 

If you would like to choose different percentages in place of P1 and P99 above, you can choose any of the percentile statistics that are available in the OUTPUT statement of the MEANS or SUMMARY procedure.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

---

These sample files and code examples are provided by SAS Institute Inc. "as is" without warranty of any kind, either express or implied, including but not limited to the implied warranties of merchantability and fitness for a particular purpose. Recipients acknowledge and agree that SAS Institute shall not be liable for any damages whatsoever arising out of their use of this material. In addition, SAS Institute will provide no support for the materials contained herein.

Operating System and Release Information